mirror of
https://git.yoctoproject.org/poky
synced 2026-07-01 05:13:39 +02:00
971d5f7b81
Where there isn't a copyright statement, add one to make it explicit. Also drop editor config lines where they were present. (From OE-Core rev: 880c1ea3edc8edef974e65b2d424fc36809ea034) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
37 lines
1021 B
Plaintext
37 lines
1021 B
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
|
|
inherit setuptools3-base python_pep517
|
|
|
|
DEPENDS += "python3-setuptools-native python3-wheel-native"
|
|
|
|
SETUPTOOLS_BUILD_ARGS ?= ""
|
|
|
|
SETUPTOOLS_SETUP_PATH ?= "${S}"
|
|
|
|
setuptools3_do_configure() {
|
|
:
|
|
}
|
|
|
|
setuptools3_do_compile() {
|
|
cd ${SETUPTOOLS_SETUP_PATH}
|
|
NO_FETCH_BUILD=1 \
|
|
STAGING_INCDIR=${STAGING_INCDIR} \
|
|
STAGING_LIBDIR=${STAGING_LIBDIR} \
|
|
${STAGING_BINDIR_NATIVE}/${PYTHON_PN}-native/${PYTHON_PN} setup.py \
|
|
bdist_wheel --verbose --dist-dir ${PEP517_WHEEL_PATH} ${SETUPTOOLS_BUILD_ARGS} || \
|
|
bbfatal_log "'${PYTHON_PN} setup.py bdist_wheel ${SETUPTOOLS_BUILD_ARGS}' execution failed."
|
|
}
|
|
setuptools3_do_compile[vardepsexclude] = "MACHINE"
|
|
do_compile[cleandirs] += "${PEP517_WHEEL_PATH}"
|
|
|
|
# This could be removed in the future but some recipes in meta-oe still use it
|
|
setuptools3_do_install() {
|
|
python_pep517_do_install
|
|
}
|
|
|
|
EXPORT_FUNCTIONS do_configure do_compile do_install
|
|
|
|
export LDSHARED="${CCLD} -shared"
|