mirror of
https://git.yoctoproject.org/poky
synced 2026-09-24 22:36:21 +02:00
ef6155e70f
As part of this update:
- drop one patch that is upstream now
- refresh one patch for new context
- backport two patches to fix the build against 6.16 (drop them in
2.14.1+
- update the license checksum, as the following change has been made
to the license:
commit 61baff6e8de2462f45006662bc34bcbf5f645ba0
Author: Michael Jeanson <mjeanson@efficios.com>
Date: Tue Jun 18 14:35:38 2024 -0400
Implement REUSE 3.0 with SPDX identifiers
Implement the full REUSE spec [1] to help with copyright and licensing
audits and compliance. This will reduce a lot of manual work for the
licensing audit required in Debian on each update and also allow using
automated tools.
For files that lacked copyright and licensing information, I used the
following guidelines. If a clear author could be determined from the git
history use it, otherwise use 'EfficiOS Inc.'. For code use
'GPL-2.0-only OR LGPL-2.1-only' unless otherwise stated, for
documentation 'CC-BY-SA-4.0' and for data files 'CC0-1.0'.
Freeform text files were converted to Markdown to allow licensing
comments.
Running the reuse tool on the repo is now succesful:
$ reuse lint
# SUMMARY
* Bad licenses: 0
* Deprecated licenses: 0
* Licenses without file extension: 0
* Missing licenses: 0
* Unused licenses: 0
* Used licenses: CC0-1.0, GPL-2.0-only, CC-BY-SA-4.0, MIT, LGPL-2.1-only
* Read errors: 0
* files with copyright information: 358 / 358
* files with license information: 358 / 358
Congratulations! Your project is compliant with version 3.0 of the REUSE Specification :-)
[1] https://reuse.software/tutorial/
Change-Id: I1755cab24a6fcec7a6c9a2136891418203ec34b8
Signed-off-by: Michael Jeanson <mjeanson@efficios.com>
Signed-off-by: Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
(From OE-Core rev: 114bc08add61adfa72470767f583eeafeb51331c)
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
44 lines
1.7 KiB
BlitzBasic
44 lines
1.7 KiB
BlitzBasic
SECTION = "devel"
|
|
SUMMARY = "Linux Trace Toolkit KERNEL MODULE"
|
|
DESCRIPTION = "The lttng-modules 2.0 package contains the kernel tracer modules"
|
|
HOMEPAGE = "https://lttng.org/"
|
|
LICENSE = "LGPL-2.1-only & GPL-2.0-only & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=018e002dbdda3306682e394ddd65fa32"
|
|
|
|
inherit module
|
|
|
|
include lttng-platforms.inc
|
|
|
|
SRC_URI = "https://lttng.org/files/${BPN}/${BPN}-${PV}.tar.bz2 \
|
|
file://0001-writeback-instrumentation-Add-missing-provider-name-.patch \
|
|
file://0002-fix-percpu-repurpose-__percpu-tag-as-a-named-address.patch \
|
|
"
|
|
|
|
# Use :append here so that the patch is applied also when using devupstream
|
|
SRC_URI:append = " file://0001-src-Kbuild-change-missing-CONFIG_TRACEPOINTS-to-warn.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "f2261e738b1dd1027640e5ba3040dee292241b847d5745766b3ba640e168c94a"
|
|
|
|
export INSTALL_MOD_DIR = "kernel/lttng-modules"
|
|
|
|
EXTRA_OEMAKE += "KERNELDIR='${STAGING_KERNEL_DIR}'"
|
|
|
|
MODULES_MODULE_SYMVERS_LOCATION = "src"
|
|
|
|
do_install:append() {
|
|
# Delete empty directories to avoid QA failures if no modules were built
|
|
if [ -d ${D}/${nonarch_base_libdir} ]; then
|
|
find ${D}/${nonarch_base_libdir} -depth -type d -empty -exec rmdir {} \;
|
|
fi
|
|
}
|
|
|
|
python do_package:prepend() {
|
|
if not os.path.exists(os.path.join(d.getVar('D'), d.getVar('nonarch_base_libdir')[1:], 'modules')):
|
|
bb.warn("%s: no modules were created; this may be due to CONFIG_TRACEPOINTS not being enabled in your kernel." % d.getVar('PN'))
|
|
}
|
|
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRC_URI:class-devupstream = "git://git.lttng.org/lttng-modules;branch=stable-2.13;protocol=https"
|
|
SRCREV:class-devupstream = "7584cfc04914cb0842a986e9808686858b9c8630"
|
|
SRCREV_FORMAT ?= "lttng_git"
|