mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
507f16e1bc
Changes with APR-util 1.6.3
*) Correct a packaging issue in 1.6.2. The contents of the release were
correct, but the top level directory was misnamed.
Changes with APR-util 1.6.2
*) SECURITY: CVE-2022-25147 (cve.mitre.org)
Integer Overflow or Wraparound vulnerability in apr_base64 functions
of Apache Portable Runtime Utility (APR-util) allows an attacker to
write beyond bounds of a buffer.
*) Teach configure how to find and build against MariaDB 10.2. PR 61517
[Kris Karas <bugs-a17 moonlit-rail.com>]
*) apr_crypto_commoncrypto: Remove stray reference to -lcrypto that
prevented commoncrypto being enabled. [Graham Leggett]
*) Add --tag=CC to libtool invocations. PR 62640. [Michael Osipov]
*) apr_dbm_gdbm: Fix handling of error codes. This makes gdbm 1.14 work.
apr_dbm_gdbm will now also return error codes starting with
APR_OS_START_USEERR, as apr_dbm_berkleydb does, instead of always
returning APR_EGENERAL. [Stefan Fritsch]
Drop backport.
(From OE-Core rev: 9eb027bebb19bfb0fb136169e865ca269890fa6f)
Signed-off-by: Alexander Kanavin <alex@linutronix.de>
Signed-off-by: Luca Ceresoli <luca.ceresoli@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
(cherry picked from commit dca707f9fecc805503e17f6db3e4c88069ac0125)
Signed-off-by: Steve Sakoman <steve@sakoman.com>
(cherry picked from commit 43cd36b178ebb602edd5919c26f8b8642736a3a8)
Signed-off-by: Steve Sakoman <steve@sakoman.com>
(cherry picked from commit e24b38a14b3520648ec418783fb74fcf61df7ff2)
Signed-off-by: Steve Sakoman <steve@sakoman.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
97 lines
3.4 KiB
BlitzBasic
97 lines
3.4 KiB
BlitzBasic
SUMMARY = "Apache Portable Runtime (APR) companion library"
|
|
HOMEPAGE = "http://apr.apache.org/"
|
|
SECTION = "libs"
|
|
DEPENDS = "apr expat"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=158aa0b1efe0c12f23d4b007ddb9a5db \
|
|
file://include/apu_version.h;endline=15;md5=823b3d1a7225df8f7b68a69c3c2b4c71"
|
|
|
|
SRC_URI = "${APACHE_MIRROR}/apr/${BPN}-${PV}.tar.gz \
|
|
file://configfix.patch \
|
|
file://configure_fixes.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "2b74d8932703826862ca305b094eef2983c27b39d5c9414442e9976a9acf1983"
|
|
|
|
EXTRA_OECONF = "--with-apr=${STAGING_BINDIR_CROSS}/apr-1-config \
|
|
--without-odbc \
|
|
--without-pgsql \
|
|
--without-sqlite2 \
|
|
--with-expat=${STAGING_DIR_HOST}${prefix}"
|
|
|
|
|
|
inherit autotools lib_package binconfig multilib_script
|
|
|
|
MULTILIB_SCRIPTS = "${PN}-dev:${bindir}/apu-1-config"
|
|
|
|
OE_BINCONFIG_EXTRA_MANGLE = " -e 's:location=source:location=installed:'"
|
|
|
|
do_configure_append() {
|
|
if [ "${CLASSOVERRIDE}" = "class-target" ]; then
|
|
cp ${STAGING_DATADIR}/apr/apr_rules.mk ${B}/build/rules.mk
|
|
sed -i -e 's#^CFLAGS=.*#CFLAGS=${TARGET_CFLAGS}#g' ${B}/build/rules.mk
|
|
fi
|
|
}
|
|
do_configure_prepend_class-native() {
|
|
mkdir ${B}/build
|
|
cp ${STAGING_DATADIR_NATIVE}/apr/apr_rules.mk ${B}/build/rules.mk
|
|
}
|
|
do_configure_append_class-native() {
|
|
sed -i "s#LIBTOOL=\$(SHELL) \$(apr_builddir)#LIBTOOL=\$(SHELL) ${STAGING_BINDIR_NATIVE}#" ${B}/build/rules.mk
|
|
# sometimes there isn't SHELL
|
|
sed -i "s#LIBTOOL=\$(apr_builddir)#LIBTOOL=${STAGING_BINDIR_NATIVE}#" ${B}/build/rules.mk
|
|
}
|
|
|
|
do_configure_prepend_class-nativesdk() {
|
|
cp ${STAGING_DATADIR}/apr/apr_rules.mk ${S}/build/rules.mk
|
|
sed -i -e 's#^CFLAGS=.*#CFLAGS=${TARGET_CFLAGS}#g' ${S}/build/rules.mk
|
|
}
|
|
|
|
do_configure_append_class-nativesdk() {
|
|
sed -i "s#\(apr_builddir\)=.*#\1=${STAGING_DATADIR}/build-1#" ${B}/build/rules.mk
|
|
sed -i "s#\(apr_builders\)=.*#\1=${STAGING_DATADIR}/build-1#" ${B}/build/rules.mk
|
|
sed -i "s#\(top_builddir\)=.*#\1=${STAGING_DATADIR}/build-1#" ${B}/build/rules.mk
|
|
sed -i "s#\(LIBTOOL=\$(apr_builddir)\).*#\1/libtool#" ${B}/build/rules.mk
|
|
}
|
|
|
|
do_install_append_class-target() {
|
|
sed -i -e 's,${STAGING_DIR_HOST},,g' \
|
|
-e 's,APU_SOURCE_DIR=.*,APR_SOURCE_DIR=,g' \
|
|
-e 's,APU_BUILD_DIR=.*,APR_BUILD_DIR=,g' ${D}${bindir}/apu-1-config
|
|
}
|
|
|
|
PACKAGECONFIG ??= "crypto gdbm"
|
|
PACKAGECONFIG[ldap] = "--with-ldap,--without-ldap,openldap"
|
|
PACKAGECONFIG[crypto] = "--with-openssl=${STAGING_DIR_HOST}${prefix} --with-crypto,--without-crypto,openssl"
|
|
PACKAGECONFIG[sqlite3] = "--with-sqlite3=${STAGING_DIR_HOST}${prefix},--without-sqlite3,sqlite3"
|
|
PACKAGECONFIG[gdbm] = "--with-dbm=gdbm --with-gdbm=${STAGING_DIR_HOST}${prefix},--without-gdbm,gdbm"
|
|
|
|
#files ${libdir}/apr-util-1/*.so are not symlinks but loadable modules thus they are packaged in ${PN}
|
|
FILES_${PN} += "${libdir}/apr-util-1/apr*${SOLIBS} ${libdir}/apr-util-1/apr*${SOLIBSDEV}"
|
|
FILES_${PN}-dev += "${libdir}/aprutil.exp ${libdir}/apr-util-1/*.la"
|
|
FILES_${PN}-staticdev += "${libdir}/apr-util-1/*.a"
|
|
|
|
INSANE_SKIP_${PN} += "dev-so"
|
|
|
|
inherit ptest
|
|
|
|
RDEPENDS_${PN}-ptest_append_libc-glibc = " glibc-gconv-iso8859-1 glibc-gconv-iso8859-2 glibc-gconv-utf-7"
|
|
RDEPENDS_${PN}-ptest += "libgcc"
|
|
|
|
do_compile_ptest() {
|
|
cd ${B}/test
|
|
oe_runmake
|
|
}
|
|
|
|
do_install_ptest() {
|
|
t=${D}${PTEST_PATH}/test
|
|
mkdir $t
|
|
for i in testall data; do \
|
|
cp -r ${B}/test/$i $t; \
|
|
done
|
|
}
|