mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 19:39:40 +01:00
67628ea66b
Fixed:
MACHINE = "beaglebone-yocto"
KERNEL_CLASSES += "kernel-fitimage"
KERNEL_IMAGETYPE_beaglebone-yocto = "fitImage"
UBOOT_MACHINE_beaglebone-yocto = "am335x_boneblack_vboot_config"
UBOOT_MKIMAGE_DTCOPTS = "-I dts -O dtb -p 2000"
UBOOT_SIGN_KEYDIR = "${TOPDIR}/conf"
UBOOT_SIGN_KEYNAME = "dev"
UBOOT_SIGN_ENABLE = "1"
IMAGE_INSTALL_remove = "kernel-image-zimage"
$ cd conf
$ openssl genrsa -F4 -out dev.key 2048
$ openssl req -batch -new -x509 -key dev.key -out dev.crt
$ cd ../
$ bitbake u-boot linux-yocto
$ grep signature tmp/deploy/images/beaglebone-yocto/*.dtb
Binary file tmp/deploy/images/beaglebone-yocto/u-boot-beaglebone-yocto-2018.07-r0.dtb matches
Binary file tmp/deploy/images/beaglebone-yocto/u-boot-beaglebone-yocto.dtb matches
Binary file tmp/deploy/images/beaglebone-yocto/u-boot.dtb matches
And there would be no signature info when rebuild from sstate:
$ bitbake u-boot linux-yocto -cclean
$ bitbake u-boot linux-yocto
$ grep signature tmp/deploy/images/beaglebone-yocto/*.dtb
No result
This s because kernel directly edit ${DEPLOY_DIR_IMAGE}/u-boot.dtb, (Note, it
is global ${DEPLOY_DIR_IMAGE}, not recipe's DEPLOYDIR), so that the modified
info is not in sstate, and would be lost when rebuild from sstate.
There are other problems in previouse code:
- The u-boot.dtb is provided by u-boot, but edited by kernel during signing, so
it should be deployed by kernel rather than u-boot.
- The u-boot.do_concat_dtb directly install files to global ${DEPLOY_DIR_IMAGE},
this is incorrect, the ${DEPLOY_DIR_IMAGE} should be installed by do_deploy.
- It seems that it assumes do_deploy depends on do_install according the comments,
but they have no relationships:
# do_concat_dtb is scheduled _before_ do_install as it overwrite the
# u-boot.bin in both DEPLOYDIR and DEPLOY_IMAGE_DIR.
- The do_concat_dtb should be run after do_compile, but it doesn't have this
dependency.
Make u-boot install u-boot.dtb to ${datadir}, kernel copies u-boot.dtb from
${STAGING_DATADIR} to ${B} and deploy it can fix the problem.
[YOCTO #12112]
Reported-by: Christian Andersen <c.andersen@kostal.com>
(From OE-Core rev: 493f70cfb177f1d452a13329647a38642bf2b161)
Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
107 lines
4.1 KiB
Plaintext
107 lines
4.1 KiB
Plaintext
# This file is part of U-Boot verified boot support and is intended to be
|
|
# inherited from u-boot recipe and from kernel-fitimage.bbclass.
|
|
#
|
|
# The signature procedure requires the user to generate an RSA key and
|
|
# certificate in a directory and to define the following variable:
|
|
#
|
|
# UBOOT_SIGN_KEYDIR = "/keys/directory"
|
|
# UBOOT_SIGN_KEYNAME = "dev" # keys name in keydir (eg. "dev.crt", "dev.key")
|
|
# UBOOT_MKIMAGE_DTCOPTS = "-I dts -O dtb -p 2000"
|
|
# UBOOT_SIGN_ENABLE = "1"
|
|
#
|
|
# As verified boot depends on fitImage generation, following is also required:
|
|
#
|
|
# KERNEL_CLASSES ?= " kernel-fitimage "
|
|
# KERNEL_IMAGETYPE ?= "fitImage"
|
|
#
|
|
# The signature support is limited to the use of CONFIG_OF_SEPARATE in U-Boot.
|
|
#
|
|
# The tasks sequence is set as below, using DEPLOY_IMAGE_DIR as common place to
|
|
# treat the device tree blob:
|
|
#
|
|
# * u-boot:do_install_append
|
|
# Install UBOOT_DTB_BINARY to datadir, so that kernel can use it for
|
|
# signing, and kernel will deploy UBOOT_DTB_BINARY after signs it.
|
|
#
|
|
# * virtual/kernel:do_assemble_fitimage
|
|
# Sign the image
|
|
#
|
|
# * u-boot:do_deploy[postfuncs]
|
|
# Deploy files like UBOOT_DTB_IMAGE, UBOOT_DTB_SYMLINK and others.
|
|
#
|
|
# For more details on signature process, please refer to U-Boot documentation.
|
|
|
|
# Signature activation.
|
|
UBOOT_SIGN_ENABLE ?= "0"
|
|
|
|
# Default value for deployment filenames.
|
|
UBOOT_DTB_IMAGE ?= "u-boot-${MACHINE}-${PV}-${PR}.dtb"
|
|
UBOOT_DTB_BINARY ?= "u-boot.dtb"
|
|
UBOOT_DTB_SYMLINK ?= "u-boot-${MACHINE}.dtb"
|
|
UBOOT_NODTB_IMAGE ?= "u-boot-nodtb-${MACHINE}-${PV}-${PR}.${UBOOT_SUFFIX}"
|
|
UBOOT_NODTB_BINARY ?= "u-boot-nodtb.${UBOOT_SUFFIX}"
|
|
UBOOT_NODTB_SYMLINK ?= "u-boot-nodtb-${MACHINE}.${UBOOT_SUFFIX}"
|
|
|
|
# Functions in this bbclass is for u-boot only
|
|
UBOOT_PN = "${@d.getVar('PREFERRED_PROVIDER_u-boot') or 'u-boot'}"
|
|
|
|
concat_dtb() {
|
|
if [ "${UBOOT_SIGN_ENABLE}" = "1" -a "${PN}" = "${UBOOT_PN}" ]; then
|
|
mkdir -p ${DEPLOYDIR}
|
|
if [ -e ${B}/${UBOOT_DTB_BINARY} ]; then
|
|
ln -sf ${UBOOT_DTB_IMAGE} ${DEPLOYDIR}/${UBOOT_DTB_BINARY}
|
|
ln -sf ${UBOOT_DTB_IMAGE} ${DEPLOYDIR}/${UBOOT_DTB_SYMLINK}
|
|
fi
|
|
|
|
if [ -f ${B}/${UBOOT_NODTB_BINARY} ]; then
|
|
install ${B}/${UBOOT_NODTB_BINARY} ${DEPLOYDIR}/${UBOOT_NODTB_IMAGE}
|
|
ln -sf ${UBOOT_NODTB_IMAGE} ${UBOOT_NODTB_SYMLINK}
|
|
ln -sf ${UBOOT_NODTB_IMAGE} ${UBOOT_NODTB_BINARY}
|
|
fi
|
|
|
|
# Concatenate U-Boot w/o DTB & DTB with public key
|
|
# (cf. kernel-fitimage.bbclass for more details)
|
|
deployed_uboot_dtb_binary='${DEPLOY_DIR_IMAGE}/${UBOOT_DTB_IMAGE}'
|
|
if [ "x${UBOOT_SUFFIX}" = "ximg" -o "x${UBOOT_SUFFIX}" = "xrom" ] && \
|
|
[ -e "$deployed_uboot_dtb_binary" ]; then
|
|
cd ${B}
|
|
oe_runmake EXT_DTB=$deployed_uboot_dtb_binary
|
|
install ${B}/${UBOOT_BINARY} ${DEPLOYDIR}/${UBOOT_IMAGE}
|
|
elif [ -e "${DEPLOYDIR}/${UBOOT_NODTB_IMAGE}" -a -e "$deployed_uboot_dtb_binary" ]; then
|
|
cd ${DEPLOYDIR}
|
|
cat ${UBOOT_NODTB_IMAGE} $deployed_uboot_dtb_binary | tee ${B}/${UBOOT_BINARY} > ${UBOOT_IMAGE}
|
|
else
|
|
bbwarn "Failure while adding public key to u-boot binary. Verified boot won't be available."
|
|
fi
|
|
fi
|
|
}
|
|
|
|
# Install UBOOT_DTB_BINARY to datadir, so that kernel can use it for
|
|
# signing, and kernel will deploy UBOOT_DTB_BINARY after signs it.
|
|
do_install_append() {
|
|
if [ "${UBOOT_SIGN_ENABLE}" = "1" -a "${PN}" = "${UBOOT_PN}" ]; then
|
|
if [ -f ${B}/${UBOOT_DTB_BINARY} ]; then
|
|
install -d ${D}${datadir}
|
|
# UBOOT_DTB_BINARY is a symlink to UBOOT_DTB_IMAGE, so we
|
|
# need both of them.
|
|
install ${B}/${UBOOT_DTB_BINARY} ${D}${datadir}/${UBOOT_DTB_IMAGE}
|
|
ln -sf ${UBOOT_DTB_IMAGE} ${D}${datadir}/${UBOOT_DTB_BINARY}
|
|
else
|
|
bbwarn "${B}/${UBOOT_DTB_BINARY} not found"
|
|
fi
|
|
fi
|
|
}
|
|
|
|
python () {
|
|
if d.getVar('UBOOT_SIGN_ENABLE') == '1' and d.getVar('PN') == d.getVar('UBOOT_PN'):
|
|
kernel_pn = d.getVar('PREFERRED_PROVIDER_virtual/kernel')
|
|
|
|
# Make "bitbake u-boot -cdeploy" deploys the signed u-boot.dtb
|
|
d.appendVarFlag('do_deploy', 'depends', ' %s:do_deploy' % kernel_pn)
|
|
|
|
# kernerl's do_deploy is a litle special, so we can't use
|
|
# do_deploy_append, otherwise it would override
|
|
# kernel_do_deploy.
|
|
d.appendVarFlag('do_deploy', 'prefuncs', ' concat_dtb')
|
|
}
|