mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 00:32:14 +02:00
c8815d2f21
If we don't do this, a stale limits.h may be detected in STAGING_DIR_TARGET which would result in a different limits.h getting generated by gcc-cross-initial that references it. The referenced limits.h will then not get found by eglibc-initial causing rather strange build failures. The simplest solution is to create a temporary sysroot containing only the things gcc-cross-initial should care about and this results in a correct limits.h file regardless of what else may have been built. (From OE-Core rev: 9c304eae0724474902fe2f3150adc6af115af9ba) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
52 lines
1.6 KiB
PHP
52 lines
1.6 KiB
PHP
DEPENDS = "virtual/${TARGET_PREFIX}binutils ${NATIVEDEPS}"
|
|
PROVIDES = "virtual/${TARGET_PREFIX}gcc-initial"
|
|
PACKAGES = ""
|
|
|
|
INHIBIT_AUTOTOOLS_DEPS = "1"
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
CROSS_TARGET_SYS_DIR_append = ".${PN}"
|
|
|
|
# This is intended to be a -very- basic config
|
|
# sysroot is needed in case we use libc-initial
|
|
EXTRA_OECONF = "--with-newlib \
|
|
--without-headers \
|
|
--disable-shared \
|
|
--disable-threads \
|
|
--disable-multilib \
|
|
--disable-__cxa_atexit \
|
|
--enable-languages=c \
|
|
${OPTSPACE} \
|
|
--program-prefix=${TARGET_PREFIX} \
|
|
--with-sysroot=${STAGING_DIR_TARGET} \
|
|
--with-build-sysroot=${GCCCROSS_BUILDSYSROOT} \
|
|
${EXTRA_OECONF_INITIAL} \
|
|
${@base_contains('DISTRO_FEATURES', 'ld-is-gold', '--with-ld=${STAGING_BINDIR_TOOLCHAIN}/${TARGET_PREFIX}ld.bfd', '', d)} \
|
|
${EXTRA_OECONF_FPU}"
|
|
|
|
|
|
GCCCROSS_BUILDSYSROOT = "${B}/tmpsysroot"
|
|
|
|
do_configure_prepend () {
|
|
sysr=${GCCCROSS_BUILDSYSROOT}${target_includedir}
|
|
mkdir -p $sysr
|
|
for t in linux asm asm-generic; do
|
|
rm -f $sysr/$t
|
|
ln -s ${STAGING_DIR_TARGET}${target_includedir}/$t $sysr/
|
|
done
|
|
}
|
|
|
|
do_compile () {
|
|
oe_runmake all-gcc all-target-libgcc
|
|
}
|
|
# fixed limits.h infact includes the so called real limits.h
|
|
# which should come from libc but when we build libc-initial
|
|
# then bunch of configure tests include fixed limits.h which in turn
|
|
# includes real limits.h but this real limits.h is not staged yet
|
|
# so we overwirte the generated include-fixed/limits.h for gcc-cross-initial
|
|
# to get rid references to real limits.h
|
|
|
|
do_install_append () {
|
|
cp gcc/include-fixed/limits.h ${D}${gcclibdir}/${TARGET_SYS}/${BINV}/include-fixed/limits.h
|
|
}
|