mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 18:32:15 +02:00
88dc0474de
Having findutils depending on coreutils-getlimits makes it harder to replace GNU coreutils with uutils-coreutils using PREFERRED_PROVIDER. Also, the findutils repository contains a version of getlimits used for the tests, so there is no need to depend on coreutils's version of getlimits. (From OE-Core rev: 4e4149c13adda3dd3b07712b1025ef077dd460b4) Signed-off-by: Etienne Cordonnier <ecordonnier@snap.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
29 lines
940 B
BlitzBasic
29 lines
940 B
BlitzBasic
require findutils.inc
|
|
|
|
# GPL-2.0-or-later (<< 4.2.32), GPL-3.0-or-later (>= 4.2.32)
|
|
LICENSE = "GPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1ebbd3e34237af26da5dc08a4e440464"
|
|
|
|
DEPENDS = "bison-native"
|
|
|
|
SRC_URI[sha256sum] = "1387e0b67ff247d2abde998f90dfbf70c1491391a59ddfecb8ae698789f0a4f5"
|
|
|
|
PACKAGECONFIG[selinux] = "--with-selinux,--without-selinux,libselinux"
|
|
# http://savannah.gnu.org/bugs/?27299
|
|
CACHED_CONFIGUREVARS += "gl_cv_func_wcwidth_works=yes"
|
|
|
|
EXTRA_OECONF += "ac_cv_path_SORT=${bindir}/sort"
|
|
|
|
# need od from coreutils for -t option
|
|
RDEPENDS:${PN}-ptest += "bash sed grep coreutils"
|
|
|
|
do_install_ptest:class-target() {
|
|
mkdir -p ${D}${PTEST_PATH}/tests/
|
|
cp ${S}/init.cfg ${D}${PTEST_PATH}
|
|
cp -r ${S}/tests/* ${D}${PTEST_PATH}/tests/
|
|
install -m 755 ${B}/find/getlimits ${D}${PTEST_PATH}/
|
|
|
|
# substitute value in run-ptest with actual version
|
|
sed -i -e 's/__run_ptest_version__/${PV}/' ${D}${PTEST_PATH}/run-ptest
|
|
}
|