mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 03:32:12 +02:00
f59a7df3fe
Removing all the S = ${WORKDIR}/git assignments works because BB_GIT_DEFAULT_DESTSUFFIX
is set to match S from bitbake.conf (which itself is set to match typical tarball
releases).
A few recipes are setting S to a sub-directory of the git tree and need
to be adjusted accordingly.
bzip2 recipe is fetching a tarball and separately cloning tests;
adjust the recipe to put the latter into 'bzip2-tests', instead of 'git'.
devupstream.bbclass no longer needs to rewrite S, and is adjusted accordingly.
Adjust scripts/lib/recipetool/append.py to not hardcode 'git' as unpack
destination.
Adjust kernel-yocto.bbclass to use the git unpack variable instead
of hardcoding 'git' (there's also removal of repetition of
string constants and a correction of workdir/unpackdir mismatch in
one of the if-else branches).
Ensure build-appliance-image recipe does not use 'git' as checkout directory for
poky repo, but rather explicitly name it 'poky'.
Ensure reproducible.py code that looks for git repositories does not
hardcode 'git' but uses the destination set by BB_GIT_DEFAULT_DESTSUFFIX.
Ensure recipetool does not write out unneeded S settings into newly
created recipes that fetch from git.
Adjust selftest to not hardcode 'git' as unpack directory.
(From OE-Core rev: f80c07019ddadaf9c5fb890faabfda7920ecd15e)
Signed-off-by: Alexander Kanavin <alex@linutronix.de>
Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
80 lines
2.6 KiB
BlitzBasic
80 lines
2.6 KiB
BlitzBasic
SUMMARY = "System performance tools"
|
|
DESCRIPTION = "The sysstat utilities are a collection of performance monitoring tools for Linux."
|
|
HOMEPAGE = "https://sysstat.github.io/"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
SECTION = "console/utils"
|
|
|
|
SRC_URI = "git://github.com/sysstat/sysstat.git;protocol=https;branch=master \
|
|
file://99_sysstat \
|
|
file://sysstat.service \
|
|
file://0001-configure.in-remove-check-for-chkconfig.patch \
|
|
"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a23a74b3f4caf9616230789d94217acb"
|
|
|
|
SRCREV = "dac10e13c70d1102aa3beea10135a3ed60520c36"
|
|
|
|
DEPENDS += "base-passwd"
|
|
|
|
# autotools-brokensep as this package doesn't use automake
|
|
inherit autotools-brokensep gettext systemd
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
|
|
PACKAGECONFIG[lm-sensors] = "--enable-sensors,--disable-sensors,lmsensors,lmsensors-libsensors"
|
|
PACKAGECONFIG[cron] = "--enable-install-cron --enable-copy-only,--disable-install-cron --disable-copy-only"
|
|
PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_system_unitdir}"
|
|
|
|
EXTRA_OECONF += "--disable-stripping"
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE:${PN} = "sysstat.service"
|
|
SYSTEMD_AUTO_ENABLE = "enable"
|
|
|
|
do_configure:prepend() {
|
|
export sa_lib_dir=${libexecdir}/sa
|
|
}
|
|
|
|
do_install() {
|
|
autotools_do_install
|
|
|
|
# Don't version the documentation
|
|
mv ${D}${docdir}/${BP} ${D}${docdir}/${BPN}
|
|
|
|
# don't install /var/log/sa when populating rootfs. Do it through volatile
|
|
rm -rf ${D}/var
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
|
|
install -d ${D}/etc/default/volatiles
|
|
install -m 0644 ${UNPACKDIR}/99_sysstat ${D}/etc/default/volatiles
|
|
fi
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
|
|
install -d ${D}${nonarch_libdir}/tmpfiles.d
|
|
echo "d ${localstatedir}/log/sa - - - -" \
|
|
> ${D}${nonarch_libdir}/tmpfiles.d/sysstat.conf
|
|
|
|
# Unless both cron and systemd are enabled, install our own
|
|
# systemd unit file. Otherwise the package will install one.
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'cron systemd', 'false', 'true', d)}; then
|
|
install -d ${D}${systemd_system_unitdir}
|
|
install -m 0644 ${UNPACKDIR}/sysstat.service ${D}${systemd_system_unitdir}
|
|
sed -i -e 's#@LIBEXECDIR@#${libexecdir}#g' ${D}${systemd_system_unitdir}/sysstat.service
|
|
fi
|
|
fi
|
|
}
|
|
|
|
pkg_postinst:${PN} () {
|
|
if [ ! -n "$D" ]; then
|
|
if [ -e /etc/init.d/populate-volatile.sh ]; then
|
|
/etc/init.d/populate-volatile.sh update
|
|
fi
|
|
fi
|
|
}
|
|
|
|
FILES:${PN} += " \
|
|
${systemd_system_unitdir} \
|
|
${nonarch_base_libdir}/systemd \
|
|
${nonarch_libdir}/tmpfiles.d \
|
|
"
|
|
|
|
TARGET_CC_ARCH += "${LDFLAGS}"
|
|
|