mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 00:32:14 +02:00
8ebe7be3d9
Currently we have a hierarchy of pkgdata directories and the code has to put together a search path and look through each in turn until it finds the data it needs. This has lead to a number of hardcoded paths and file globing which is unpredictable and undesirable. Worse, certain tricks that should be easy like a GL specific package architecture become problematic with the curretn search paths. With the modern sstate code, we can do better and construct a single pkgdata directory for each machine in just the same way as we do for the sysroot. This is already tried and well tested. With such a single directory, all the code that iterated through multiple pkgdata directories and simply be removed and give a significant simplification of the code. Even existing build directories adapt to the change well since the package contents doesn't change, just the location they're installed to and the stamp for them. The only complication is the we need a different shlibs directory for each multilib. These are only used by package.bbclass and the simple fix is to add MLPREFIX to the shlib directory name. This means the multilib packages will repackage and the sstate checksum will change but an existing build directory will adapt to the changes safely. It is close to release however I believe the benefits this patch give us are worth consideration for inclusion and give us more options for dealing with problems like the GL one. It also sets the ground work well for shlibs improvements in 1.6. (From OE-Core rev: 1b8e4abd2d9c0901d38d89d0f944fe1ffd019379) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
122 lines
4.2 KiB
PHP
122 lines
4.2 KiB
PHP
DESCRIPTION = "The GNU cc and gcc C compilers."
|
|
HOMEPAGE = "http://www.gnu.org/software/gcc/"
|
|
SECTION = "devel"
|
|
LICENSE = "GPL"
|
|
|
|
NATIVEDEPS = ""
|
|
|
|
inherit autotools gettext
|
|
|
|
def get_gcc_fpu_setting(bb, d):
|
|
if d.getVar('ARMPKGSFX_EABI', True) == "hf" and d.getVar('TRANSLATED_TARGET_ARCH', True) == "arm":
|
|
return "--with-float=hard"
|
|
if d.getVar('TARGET_FPU', True) in [ 'soft' ]:
|
|
return "--with-float=soft"
|
|
if d.getVar('TARGET_FPU', True) in [ 'ppc-efd' ]:
|
|
return "--enable-e500_double"
|
|
return ""
|
|
|
|
def get_gcc_mips_plt_setting(bb, d):
|
|
if d.getVar('TRANSLATED_TARGET_ARCH', True) in [ 'mips', 'mipsel' ] and 'mplt' in d.getVar('DISTRO_FEATURES',1).split() :
|
|
return "--with-mips-plt"
|
|
return ""
|
|
|
|
def get_gcc_multiarch_setting(bb, d):
|
|
target_arch = d.getVar('TRANSLATED_TARGET_ARCH', True)
|
|
multiarch_options = {
|
|
"i586": "--enable-targets=all",
|
|
"powerpc": "--enable-targets=powerpc64",
|
|
"sparc": "--enable-targets=all",
|
|
}
|
|
|
|
if 'multiarch' in d.getVar('DISTRO_FEATURES', True).split() :
|
|
if target_arch in multiarch_options :
|
|
return multiarch_options[target_arch]
|
|
return ""
|
|
|
|
# this is used by the multilib setup of gcc
|
|
def get_tune_parameters(tune, d):
|
|
availtunes = d.getVar('AVAILTUNES', True)
|
|
if tune not in availtunes.split():
|
|
bb.error('The tune: %s is not one of the available tunes: %s', tune or None, availtunes)
|
|
|
|
localdata = bb.data.createCopy(d)
|
|
override = ':tune-' + tune
|
|
localdata.setVar('OVERRIDES', localdata.getVar('OVERRIDES', False) + override)
|
|
bb.data.update_data(localdata)
|
|
|
|
retdict = {}
|
|
retdict['tune'] = tune
|
|
retdict['ccargs'] = localdata.getVar('TUNE_CCARGS', True)
|
|
retdict['features'] = localdata.getVar('TUNE_FEATURES', True)
|
|
# BASELIB is used by the multilib code to change library paths
|
|
retdict['baselib'] = localdata.getVar('BASE_LIB', True) or localdata.getVar('BASELIB', True)
|
|
retdict['arch'] = localdata.getVar('TUNE_ARCH', True)
|
|
retdict['abiextension'] = localdata.getVar('ABIEXTENSION', True)
|
|
retdict['target_fpu'] = localdata.getVar('TARGET_FPU', True)
|
|
retdict['pkgarch'] = localdata.getVar('TUNE_PKGARCH', True)
|
|
retdict['package_extra_archs'] = localdata.getVar('PACKAGE_EXTRA_ARCHS', True)
|
|
return retdict
|
|
|
|
get_tune_parameters[vardepsexclude] = "AVAILTUNES"
|
|
|
|
DEBIANNAME_${MLPREFIX}libgcc = "libgcc1"
|
|
|
|
MIRRORS =+ "\
|
|
${GNU_MIRROR}/gcc ftp://gcc.gnu.org/pub/gcc/releases/ \n \
|
|
${GNU_MIRROR}/gcc ftp://gd.tuwien.ac.at/gnu/gcc/ \n \
|
|
${GNU_MIRROR}/gcc http://mirrors.rcn.net/pub/sourceware/gcc/releases/ \n \
|
|
${GNU_MIRROR}/gcc http://gcc.get-software.com/releases/ \n \
|
|
${GNU_MIRROR}/gcc http://gcc.get-software.com/releases/ \n \
|
|
"
|
|
|
|
#
|
|
# Set some default values
|
|
#
|
|
gcclibdir = "${libdir}/gcc"
|
|
BINV = "${PV}"
|
|
#S = "${WORKDIR}/gcc-${PV}"
|
|
S = "${TMPDIR}/work-shared/gcc-${PV}-${PR}/gcc-${PV}"
|
|
B = "${WORKDIR}/gcc-${PV}/build.${HOST_SYS}.${TARGET_SYS}"
|
|
|
|
# SS means Shared Stamps directory
|
|
SS = "${TMPDIR}/stamps/work-shared/gcc-${PV}-${PR}"
|
|
do_fetch[stamp-base] = "${SS}"
|
|
do_unpack[stamp-base] = "${SS}"
|
|
do_patch[stamp-base] = "${SS}"
|
|
SSCLEAN = "${TMPDIR}/stamps/work-shared/gcc-[0-9]*-*"
|
|
do_fetch[stamp-base-clean] = "${SSCLEAN}"
|
|
do_unpack[stamp-base-clean] = "${SSCLEAN}"
|
|
do_patch[stamp-base-clean] = "${SSCLEAN}"
|
|
|
|
# SW means Shared Work directory
|
|
SW = "${TMPDIR}/work-shared/gcc-${PV}-${PR}"
|
|
WORKDIR_task-unpack = "${SW}"
|
|
WORKDIR_task-patch = "${SW}"
|
|
|
|
target_includedir ?= "${includedir}"
|
|
target_libdir ?= "${libdir}"
|
|
target_base_libdir ?= "${base_libdir}"
|
|
target_prefix ?= "${prefix}"
|
|
|
|
CLEANFUNCS += "workshared_clean"
|
|
# The do_clean should be exclusive since share ${S}
|
|
do_clean[lockfiles] = "${SW}.clean.lock"
|
|
|
|
python workshared_clean () {
|
|
"""clear the source directory"""
|
|
dir = d.expand("${SW}")
|
|
bb.note("Removing " + dir)
|
|
oe.path.remove(dir)
|
|
|
|
"""clear the the stamps in work-shared"""
|
|
dir = "%s.*" % bb.data.expand(d.getVarFlag('do_fetch', 'stamp-base', True), d)
|
|
bb.note("Removing " + dir)
|
|
oe.path.remove(dir)
|
|
}
|
|
|
|
# We need to ensure that for the shared work directory, the do_patch singatures match
|
|
# The real WORKDIR location isn't a dependency for the shared workdir.
|
|
src_patches[vardepsexclude] = "WORKDIR"
|
|
should_apply[vardepsexclude] += "PN"
|