mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 00:32:12 +02:00
1b25cf710e
If Clutter is building the Wayland backend but not the X11 backend, the Cogl support doesn't get enabled so the Wayland backend (which uses it) fails to compile. Backport a fix from upstream to fix this situation. (From OE-Core rev: 6df36a004210901acceff4a201d0f910d99eccfe) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.8 KiB
PHP
48 lines
1.8 KiB
PHP
DESCRIPTION = "Clutter graphics library"
|
|
HOMEPAGE = "http://www.clutter-project.org/"
|
|
LICENSE = "LGPLv2.1+"
|
|
|
|
inherit clutter
|
|
|
|
SRC_URI += "file://enable_tests.patch \
|
|
file://fix-wayland-deps.patch"
|
|
|
|
DEPENDS = "pango glib-2.0 json-glib atk udev cogl-1.0"
|
|
PACKAGES =+ "${PN}-examples"
|
|
AUTOTOOLS_AUXDIR = "${S}/build"
|
|
|
|
EDEPENDS_X11 = "virtual/libx11 libxi libxfixes"
|
|
EDEPENDS_GLX = "virtual/libgl"
|
|
EDEPENDS_EGL = "virtual/egl"
|
|
EDEPENDS_WAYLAND = "wayland libxkbcommon gdk-pixbuf"
|
|
|
|
EDEPENDS_EVDEV = "libxkbcommon"
|
|
ERDEPENDS_EVDEV = "xkeyboard-config"
|
|
|
|
# Disable pretty much everything, override in platform specific set up
|
|
EXTRA_OECONF += "--disable-introspection \
|
|
--disable-quartz-backend \
|
|
--disable-win32-backend \
|
|
--disable-gdk-backend \
|
|
--disable-cex100-backend \
|
|
--disable-tslib-input \
|
|
"
|
|
|
|
PACKAGECONFIG[x11] = "--enable-x11-backend,--disable-x11-backend,${EDEPENDS_X11}"
|
|
PACKAGECONFIG[glx] = ",,${EDEPENDS_X11} ${EDEPENDS_GLX}"
|
|
PACKAGECONFIG[egl] = "--enable-egl-backend,--disable-egl-backend,${EDEPENDS_EGL}"
|
|
PACKAGECONFIG[evdev] = "--enable-evdev-input,--disable-evdev-input,${EDEPENDS_EVDEV},${ERDEPENDS_EVDEV}"
|
|
PACKAGECONFIG[wayland] = "--enable-wayland-backend,--disable-wayland-backend,${EDEPENDS_WAYLAND}"
|
|
PACKAGECONFIG[wayland-compositor] = "--enable-wayland-compositor,--disable-wayland-compositor,wayland"
|
|
|
|
# Default configuration, distros might want to override
|
|
PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'wayland', 'wayland', '', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'x11', 'glx x11', '', d)}"
|
|
|
|
FILES_${PN}-examples = "${bindir}/test-* ${pkgdatadir}/redhand.png"
|
|
|
|
do_configure_prepend() {
|
|
# see https://bugzilla.gnome.org/show_bug.cgi?id=661128 for this
|
|
touch -t 200001010000 ${S}/po/clutter-1.0.pot
|
|
}
|