mirror of
https://git.yoctoproject.org/poky
synced 2026-02-22 17:39:39 +01:00
fa7c52356a
Changes from 1.9.2 to 1.9.3: ---------------------------- * Fix a bunch of minor code issues pointed out using Clang static analyzer. * New API: pkgconf_solution_free(), which frees a compiled solution graph. * Fix behavior when overriding global variables with '--define-variable'. (From OE-Core rev: a48dc992ebf8e664bde4de61ba937a87fc142533) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Luca Ceresoli <luca.ceresoli@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
68 lines
2.8 KiB
BlitzBasic
68 lines
2.8 KiB
BlitzBasic
SUMMARY = "pkgconf provides compiler and linker configuration for development frameworks."
|
|
DESCRIPTION = "pkgconf is a program which helps to configure compiler and linker \
|
|
flags for development frameworks. It is similar to pkg-config from \
|
|
freedesktop.org, providing additional functionality while also maintaining \
|
|
compatibility."
|
|
HOMEPAGE = "http://pkgconf.org"
|
|
BUGTRACKER = "https://github.com/pkgconf/pkgconf/issues"
|
|
SECTION = "devel"
|
|
PROVIDES += "pkgconfig"
|
|
RPROVIDES:${PN} += "pkgconfig"
|
|
|
|
# The pkgconf license seems to be functionally equivalent to BSD-2-Clause or
|
|
# ISC, but has different wording, so needs its own name.
|
|
LICENSE = "pkgconf"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2214222ec1a820bd6cc75167a56925e0"
|
|
|
|
SRC_URI = "\
|
|
https://distfiles.dereferenced.org/pkgconf/pkgconf-${PV}.tar.xz \
|
|
file://pkg-config-wrapper \
|
|
file://pkg-config-native.in \
|
|
file://pkg-config-esdk.in \
|
|
"
|
|
SRC_URI[sha256sum] = "5fb355b487d54fb6d341e4f18d4e2f7e813a6622cf03a9e87affa6a40565699d"
|
|
|
|
inherit autotools
|
|
|
|
EXTRA_OECONF += "--with-pkg-config-dir='${libdir}/pkgconfig:${datadir}/pkgconfig'"
|
|
|
|
do_install:append () {
|
|
# Install a wrapper which deals, as much as possible with pkgconf vs
|
|
# pkg-config compatibility issues.
|
|
install -m 0755 "${WORKDIR}/pkg-config-wrapper" "${D}${bindir}/pkg-config"
|
|
}
|
|
|
|
do_install:append:class-native () {
|
|
# Install a pkg-config-native wrapper that will use the native sysroot instead
|
|
# of the MACHINE sysroot, for using pkg-config when building native tools.
|
|
sed -e "s|@PATH_NATIVE@|${PKG_CONFIG_PATH}|" \
|
|
< ${WORKDIR}/pkg-config-native.in > ${B}/pkg-config-native
|
|
install -m755 ${B}/pkg-config-native ${D}${bindir}/pkg-config-native
|
|
sed -e "s|@PATH_NATIVE@|${PKG_CONFIG_PATH}|" \
|
|
-e "s|@LIBDIR_NATIVE@|${PKG_CONFIG_LIBDIR}|" \
|
|
< ${WORKDIR}/pkg-config-esdk.in > ${B}/pkg-config-esdk
|
|
install -m755 ${B}/pkg-config-esdk ${D}${bindir}/pkg-config-esdk
|
|
}
|
|
|
|
# When using the RPM generated automatic package dependencies, some packages
|
|
# will end up requiring 'pkgconfig(pkg-config)'. Allow this behavior by
|
|
# specifying an appropriate provide.
|
|
RPROVIDES:${PN} += "pkgconfig(pkg-config)"
|
|
|
|
# Include pkg.m4 in the main package, leaving libpkgconf dev files in -dev
|
|
FILES:${PN}-dev:remove = "${datadir}/aclocal"
|
|
FILES:${PN} += "${datadir}/aclocal"
|
|
|
|
BBCLASSEXTEND += "native nativesdk"
|
|
|
|
pkgconf_sstate_fixup_esdk () {
|
|
if [ "${BB_CURRENTTASK}" = "populate_sysroot_setscene" -a "${WITHIN_EXT_SDK}" = "1" ] ; then
|
|
pkgconfdir="${SSTATE_INSTDIR}/recipe-sysroot-native/${bindir_native}"
|
|
mv $pkgconfdir/pkg-config $pkgconfdir/pkg-config.real
|
|
ln -rs $pkgconfdir/pkg-config-esdk $pkgconfdir/pkg-config
|
|
sed -i -e "s|^pkg-config|pkg-config.real|" $pkgconfdir/pkg-config-native
|
|
fi
|
|
}
|
|
|
|
SSTATEPOSTUNPACKFUNCS:append:class-native = " pkgconf_sstate_fixup_esdk"
|