mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 18:32:15 +02:00
a7cfa2ee05
* Correct the command location in ptest scripts such as update the line "#!/bin/awk -f" to "#!/usr/bin/awk -f" in the file /usr/lib64/gawk/ptest/test/fcall_exit2.awk belongs to package gawk-ptest and the line "#!/usr/local/bin/gawk -f" to "#!/usr/bin/gawk -f" in the file /usr/lib64/gawk/ptest/test/fnarydel.awk (From OE-Core rev: 66aa9f1424202a583acd168182ae13ea68e2ab15) Signed-off-by: Li Wang <li.wang@windriver.com> Signed-off-by: Mingli Yu <Mingli.Yu@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
1.5 KiB
BlitzBasic
51 lines
1.5 KiB
BlitzBasic
SUMMARY = "GNU awk text processing utility"
|
|
DESCRIPTION = "The GNU version of awk, a text processing utility. \
|
|
Awk interprets a special-purpose programming language to do \
|
|
quick and easy text pattern matching and reformatting jobs."
|
|
HOMEPAGE = "https://www.gnu.org/software/gawk/"
|
|
BUGTRACKER = "bug-gawk@gnu.org"
|
|
SECTION = "console/utils"
|
|
|
|
# gawk <= 3.1.5: GPLv2
|
|
# gawk >= 3.1.6: GPLv3
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
DEPENDS += "readline"
|
|
|
|
PACKAGECONFIG[mpfr] = "--with-mpfr,--without-mpfr, mpfr"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/gawk/gawk-${PV}.tar.gz \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "0256724a0af50cb83ac92f833488673d"
|
|
SRC_URI[sha256sum] = "2b23d51503b2df9a41aa6fddc6002ad7ebf2a386ac19dc1b6be0dd48b0acf6db"
|
|
|
|
inherit autotools gettext texinfo update-alternatives
|
|
|
|
FILES_${PN} += "${datadir}/awk"
|
|
FILES_${PN}-dev += "${libdir}/${BPN}/*.la"
|
|
|
|
ALTERNATIVE_${PN} = "awk"
|
|
ALTERNATIVE_TARGET[awk] = "${bindir}/gawk"
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
do_install_append() {
|
|
# remove the link since we don't package it
|
|
rm ${D}${bindir}/awk
|
|
}
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
mkdir ${D}${PTEST_PATH}/test
|
|
for i in `grep -vE "@|^$|#|Gt-dummy" ${S}/test/Maketests |awk -F: '{print $1}'` Maketests inclib.awk; \
|
|
do cp ${S}/test/$i* ${D}${PTEST_PATH}/test; \
|
|
done
|
|
sed -i -e 's|/usr/local/bin|${bindir}|g' \
|
|
-e 's|#!${base_bindir}/awk|#!${bindir}/awk|g' ${D}${PTEST_PATH}/test/*.awk
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|