mirror of
https://git.yoctoproject.org/poky
synced 2026-04-26 09:32:14 +02:00
262c81e3ca
Starting from tar 1.29 the --exclude option won't work anymore if is not used before the path. There are some recipes that copy the ptest using tar and --exclude option. This fixes these for OE-Core recipes. [YOCTO #9763] (From OE-Core rev: 2ba55933c81f78f4e4c36e21c59e935f74ce0f52) Signed-off-by: Mariano Lopez <mariano.lopez@linux.intel.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.4 KiB
PHP
43 lines
1.4 KiB
PHP
SUMMARY = "Utilities for managing POSIX Access Control Lists"
|
|
HOMEPAGE = "http://savannah.nongnu.org/projects/acl/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "LGPLv2.1+ & GPLv2+"
|
|
LICENSE_${PN} = "GPLv2+"
|
|
LICENSE_lib${BPN} = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://doc/COPYING;md5=c781d70ed2b4d48995b790403217a249 \
|
|
file://doc/COPYING.LGPL;md5=9e9a206917f8af112da634ce3ab41764"
|
|
|
|
DEPENDS = "attr"
|
|
SRC_URI = "${SAVANNAH_GNU_MIRROR}/acl/${BP}.src.tar.gz \
|
|
file://run-ptest \
|
|
file://acl-fix-the-order-of-expected-output-of-getfacl.patch \
|
|
file://test-fix-insufficient-quoting-of.patch \
|
|
file://test-fixups-on-SELinux-machines-for-root-testcases.patch \
|
|
file://test-fix-directory-permissions.patch \
|
|
"
|
|
|
|
require ea-acl.inc
|
|
|
|
# avoid RPATH hardcode to staging dir
|
|
do_configure_append() {
|
|
sed -i ${S}/config.status -e s,^\\\(hardcode_into_libs=\\\).*$,\\1\'no\',
|
|
${S}/config.status
|
|
}
|
|
|
|
# libdir should point to .la
|
|
do_install_append() {
|
|
sed -i ${D}${libdir}/libacl.la -e \
|
|
s,^libdir=\'${base_libdir}\'$,libdir=\'${libdir}\',
|
|
}
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
tar -c --exclude=nfs test/ | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
mkdir ${D}${PTEST_PATH}/include
|
|
cp ${S}/include/builddefs ${S}/include/buildmacros ${S}/include/buildrules ${D}${PTEST_PATH}/include/
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest = "acl bash coreutils perl perl-module-filehandle perl-module-getopt-std perl-module-posix shadow"
|