mirror of
https://git.yoctoproject.org/poky
synced 2026-02-10 10:43:02 +01:00
ceefa75ac0
Multiple files have " ," instead of ", " in expressions. This changes them to conform to the way the rest of them are done. Found and corrected via: git ls-files | xargs sed --follow-symlinks -i 's/ ,d/, d/g' (From OE-Core rev: 36c3afd2dd8bded02ea8f255e89a09ebd75c795b) Signed-off-by: Jon Mason <jon.mason@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
40 lines
1.3 KiB
Plaintext
40 lines
1.3 KiB
Plaintext
#
|
|
# Creates a root filesystem out of rpm packages
|
|
#
|
|
|
|
ROOTFS_PKGMANAGE = "rpm dnf"
|
|
|
|
# dnf is using our custom distutils, and so will fail without these
|
|
export STAGING_INCDIR
|
|
export STAGING_LIBDIR
|
|
|
|
# Add 100Meg of extra space for dnf
|
|
IMAGE_ROOTFS_EXTRA_SPACE_append = "${@bb.utils.contains("PACKAGE_INSTALL", "dnf", " + 102400", "", d)}"
|
|
|
|
# Dnf is python based, so be sure python3-native is available to us.
|
|
EXTRANATIVEPATH += "python3-native"
|
|
|
|
# opkg is needed for update-alternatives
|
|
RPMROOTFSDEPENDS = "rpm-native:do_populate_sysroot \
|
|
dnf-native:do_populate_sysroot \
|
|
createrepo-c-native:do_populate_sysroot \
|
|
opkg-native:do_populate_sysroot"
|
|
|
|
do_rootfs[depends] += "${RPMROOTFSDEPENDS}"
|
|
do_populate_sdk[depends] += "${RPMROOTFSDEPENDS}"
|
|
|
|
do_rootfs[recrdeptask] += "do_package_write_rpm do_package_qa"
|
|
do_rootfs[vardeps] += "PACKAGE_FEED_URIS"
|
|
|
|
python () {
|
|
if d.getVar('BUILD_IMAGES_FROM_FEEDS'):
|
|
flags = d.getVarFlag('do_rootfs', 'recrdeptask')
|
|
flags = flags.replace("do_package_write_rpm", "")
|
|
flags = flags.replace("do_deploy", "")
|
|
flags = flags.replace("do_populate_sysroot", "")
|
|
d.setVarFlag('do_rootfs', 'recrdeptask', flags)
|
|
d.setVar('RPM_PREPROCESS_COMMANDS', '')
|
|
d.setVar('RPM_POSTPROCESS_COMMANDS', '')
|
|
|
|
}
|