mirror of
https://git.yoctoproject.org/poky
synced 2026-02-28 12:29:40 +01:00
6fb493aa1b
Noteworthy changes in version 1.6.5 (2016-02-09) [C20/A0/R5] ------------------------------------------------ * Mitigate side-channel attack on ECDH with Weierstrass curves [CVE-2015-7511]. See http://www.cs.tau.ac.IL/~tromer/ecdh/ for details. * Fix build problem on Solaris. (From OE-Core rev: 1146a4bb3af167c75bdea3e75e6f1e80b45cc721) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.5 KiB
PHP
48 lines
1.5 KiB
PHP
SUMMARY = "General purpose cryptographic library based on the code from GnuPG"
|
|
HOMEPAGE = "http://directory.fsf.org/project/libgcrypt/"
|
|
BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
|
|
SECTION = "libs"
|
|
|
|
# helper program gcryptrnd and getrandom are under GPL, rest LGPL
|
|
LICENSE = "GPLv2+ & LGPLv2.1+ & GPLv3+"
|
|
LICENSE_${PN} = "LGPLv2.1+"
|
|
LICENSE_${PN}-dev = "GPLv2+ & LGPLv2.1+"
|
|
LICENSE_dumpsexp-dev = "GPLv3+"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://COPYING.LIB;md5=bbb461211a33b134d42ed5ee802b37ff"
|
|
|
|
DEPENDS = "libgpg-error libcap"
|
|
|
|
SRC_URI = "ftp://ftp.gnupg.org/gcrypt/libgcrypt/libgcrypt-${PV}.tar.gz \
|
|
file://add-pkgconfig-support.patch \
|
|
file://libgcrypt-fix-building-error-with-O2-in-sysroot-path.patch \
|
|
file://fix-ICE-failure-on-mips-with-option-O-and-g.patch \
|
|
"
|
|
|
|
BINCONFIG = "${bindir}/libgcrypt-config"
|
|
|
|
inherit autotools texinfo binconfig-disabled pkgconfig
|
|
|
|
EXTRA_OECONF = "--disable-asm --with-capabilities"
|
|
|
|
do_configure_prepend () {
|
|
# Else this could be used in preference to the one in aclocal-copy
|
|
rm -f ${S}/m4/gpg-error.m4
|
|
}
|
|
|
|
# libgcrypt.pc is added locally and thus installed here
|
|
do_install_append() {
|
|
install -d ${D}/${libdir}/pkgconfig
|
|
install -m 0644 ${B}/src/libgcrypt.pc ${D}/${libdir}/pkgconfig/
|
|
}
|
|
|
|
PACKAGES =+ "dumpsexp-dev"
|
|
|
|
FILES_${PN}-dev += "${bindir}/hmac256"
|
|
FILES_dumpsexp-dev += "${bindir}/dumpsexp"
|
|
|
|
ARM_INSTRUCTION_SET = "arm"
|
|
|
|
BBCLASSEXTEND = "native"
|