mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 01:06:37 +01:00
b70c9154e4
When building an image recipe, you can now build a companion SDK by calling the populate_sdk task: bitbake -c populate_sdk core-image-minimal Note: there are still issues w/ the SDK not working completely with multilibs. A lock is required between rootfs and populate_sdk activities to prevent configuration file clashes and similar package management problems in ipk and deb based systems. (RPM already had a lock for a different reason.) (From OE-Core rev: a0de2a56f19ae4d8cd88e46e96917a7a019fe1ab) Signed-off-by: Mark Hatle <mark.hatle@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.7 KiB
Plaintext
53 lines
1.7 KiB
Plaintext
do_populate_sdk[depends] += "opkg-native:do_populate_sysroot opkg-utils-native:do_populate_sysroot"
|
|
do_populate_sdk[recrdeptask] += "do_package_write_ipk"
|
|
|
|
do_populate_sdk[lockfiles] += "${WORKDIR}/ipk.lock"
|
|
|
|
populate_sdk_ipk() {
|
|
|
|
rm -f ${IPKGCONF_TARGET}
|
|
touch ${IPKGCONF_TARGET}
|
|
rm -f ${IPKGCONF_SDK}
|
|
touch ${IPKGCONF_SDK}
|
|
|
|
package_update_index_ipk
|
|
package_generate_ipkg_conf
|
|
|
|
export INSTALL_PACKAGES_LINGUAS_IPK=""
|
|
export INSTALL_TASK_IPK="populate_sdk"
|
|
|
|
#install target
|
|
export INSTALL_ROOTFS_IPK="${SDK_OUTPUT}/${SDKTARGETSYSROOT}"
|
|
export INSTALL_CONF_IPK="${IPKGCONF_TARGET}"
|
|
export INSTALL_PACKAGES_IPK="${TOOLCHAIN_TARGET_TASK}"
|
|
export INSTALL_PACKAGES_ATTEMPTONLY_IPK="${TOOLCHAIN_TARGET_TASK_ATTEMPTONLY}"
|
|
|
|
export D=${INSTALL_ROOTFS_IPK}
|
|
export OFFLINE_ROOT=${INSTALL_ROOTFS_IPK}
|
|
export IPKG_OFFLINE_ROOT=${INSTALL_ROOTFS_IPK}
|
|
export OPKG_OFFLINE_ROOT=${IPKG_OFFLINE_ROOT}
|
|
|
|
package_install_internal_ipk
|
|
|
|
#install host
|
|
export INSTALL_ROOTFS_IPK="${SDK_OUTPUT}"
|
|
export INSTALL_CONF_IPK="${IPKGCONF_SDK}"
|
|
export INSTALL_PACKAGES_IPK="${TOOLCHAIN_HOST_TASK}"
|
|
export INSTALL_PACKAGES_ATTEMPTONLY_IPK="${TOOLCHAIN_HOST_TASK_ATTEMPTONLY}"
|
|
|
|
package_install_internal_ipk
|
|
|
|
#post clean up
|
|
install -d ${SDK_OUTPUT}/${SDKTARGETSYSROOT}/${sysconfdir}
|
|
install -m 0644 ${IPKGCONF_TARGET} ${IPKGCONF_SDK} ${SDK_OUTPUT}/${SDKTARGETSYSROOT}/${sysconfdir}/
|
|
|
|
install -d ${SDK_OUTPUT}/${SDKPATHNATIVE}/${sysconfdir}
|
|
install -m 0644 ${IPKGCONF_SDK} ${SDK_OUTPUT}/${SDKPATHNATIVE}/${sysconfdir}/
|
|
|
|
install -d ${SDK_OUTPUT}/${SDKPATHNATIVE}${localstatedir_nativesdk}/lib/opkg
|
|
mv ${SDK_OUTPUT}/var/lib/opkg/* ${SDK_OUTPUT}/${SDKPATHNATIVE}${localstatedir_nativesdk}/lib/opkg/
|
|
rm -Rf ${SDK_OUTPUT}/var
|
|
|
|
populate_sdk_log_check populate_sdk
|
|
}
|