mirror of
https://git.yoctoproject.org/poky
synced 2026-02-12 11:43:04 +01:00
a7b443ae3d
Fixes errors like /home/kraj/work/angstrom/sources/openembedded-core/build/tmp-eglibc/work/armv5te-oe-linux-gnueabi/gdb-7.4.1-r0.0/gdb-7.4.1/gdb/linux-nat.h:79:18: error: field 'siginfo' has incomplete type (From OE-Core rev: 6e5b37403dd4d0a9a249535d07b36bbae98cadd6) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
70 lines
2.2 KiB
PHP
70 lines
2.2 KiB
PHP
DESCRIPTION = "gdb - GNU debugger"
|
|
HOMEPAGE = "http://www.gnu.org/software/gdb/"
|
|
LICENSE="GPLv3+"
|
|
SECTION = "devel"
|
|
DEPENDS = "expat ncurses readline ${LTTNGUST}"
|
|
|
|
LTTNGUST = "lttng-ust"
|
|
LTTNGUST_libc-uclibc = ""
|
|
LTTNGUST_mips = ""
|
|
LTTNGUST_mipsel = ""
|
|
LTTNGUST_mips64 = ""
|
|
LTTNGUST_mips64el = ""
|
|
LTTNGUST_sh4 = ""
|
|
|
|
INC_PR = "r1"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552 \
|
|
file://COPYING.LIB;md5=9f604d8a4f8e74f4f5140845a21b6674 \
|
|
file://COPYING3;md5=d32239bcb673463ab874e80d47fae504 \
|
|
file://COPYING3.LIB;md5=6a6a8e020838b23406c81b19c1d46df6"
|
|
inherit autotools
|
|
|
|
SRC_URI = "${GNU_MIRROR}/gdb/gdb-${PV}.tar.gz \
|
|
file://no-werror.patch"
|
|
|
|
SRC_URI[md5sum] = "5fb7fca9ef7a9e3cfee0e2f2c0e52051"
|
|
SRC_URI[sha256sum] = "f99d2be831ead324712ae4f11868e07e545272f10aac4186060f1386f2629b38"
|
|
|
|
export CC_FOR_BUILD = "${BUILD_CC}"
|
|
export CXX_FOR_BUILD = "${BUILD_CXX}"
|
|
export CPP_FOR_BUILD = "${BUILD_CPP}"
|
|
export CFLAGS_FOR_BUILD = "${BUILD_CFLAGS}"
|
|
export CXXFLAGS_FOR_BUILD = "${BUILD_CXXFLAGS}"
|
|
export CPPFLAGS_FOR_BUILD = "${BUILD_CPPFLAGS}"
|
|
|
|
B = "${WORKDIR}/build-${TARGET_SYS}"
|
|
|
|
EXTRA_OEMAKE = "'SUBDIRS=intl mmalloc libiberty opcodes bfd sim gdb etc utils'"
|
|
|
|
EXPAT = "--with-expat --with-libexpat-prefix=${STAGING_DIR_HOST}"
|
|
|
|
EXTRA_OECONF = "--disable-gdbtk --disable-tui --disable-x \
|
|
--with-curses --disable-multilib --with-system-readline --disable-sim \
|
|
${GDBPROPREFIX} ${EXPAT} \
|
|
${@base_contains('DISTRO_FEATURES', 'multiarch', '--enable-64-bit-bfd', '', d)} \
|
|
"
|
|
|
|
GDBPROPREFIX = "--program-prefix=''"
|
|
|
|
do_configure () {
|
|
# override this function to avoid the autoconf/automake/aclocal/autoheader
|
|
# calls for now
|
|
(cd ${S} && gnu-configize) || die "failure in running gnu-configize"
|
|
oe_runconf
|
|
}
|
|
|
|
# we don't want gdb to provide bfd/iberty/opcodes, which instead will override the
|
|
# right bits installed by binutils.
|
|
do_install_append() {
|
|
rm -rf ${D}${libdir}
|
|
rm -rf ${D}${includedir}
|
|
rm -rf ${D}${datadir}/locale
|
|
}
|
|
|
|
RRECOMMENDS_gdb_append_linux = " glibc-thread-db "
|
|
RRECOMMENDS_gdb_append_linux-gnueabi = " glibc-thread-db "
|
|
RRECOMMENDS_gdbserver_append_linux = " glibc-thread-db "
|
|
RRECOMMENDS_gdbserver_append_linux-gnueabi = " glibc-thread-db "
|
|
|