mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
d53c80fd9c
If cross-compiling, apr's configure script assumes that pid_t is 64-bit which is wrong - it appears that 32-bit is a safe assumption for Linux no matter what the architecture, so use that instead by default. This fixes Apache writing garbage to its pid file when built using apr produced from this recipe. (From OE-Core rev: 81eb71736a4d14abe85d810f9862d8a9421e9ef5) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
63 lines
1.9 KiB
BlitzBasic
63 lines
1.9 KiB
BlitzBasic
DESCRIPTION = "Apache Portable Runtime (APR) library"
|
|
HOMEPAGE = "http://apr.apache.org/"
|
|
SECTION = "libs"
|
|
DEPENDS = "util-linux"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=0c35ff3c4c83b89d2f076e315caac28b \
|
|
file://include/apr_lib.h;endline=17;md5=ee42fa7575dc40580a9e01c1b75fae96"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
PR = "r1"
|
|
|
|
SRC_URI = "${APACHE_MIRROR}/apr/${BPN}-${PV}.tar.bz2 \
|
|
file://configure_fixes.patch \
|
|
file://cleanup.patch \
|
|
file://configfix.patch"
|
|
|
|
SRC_URI[md5sum] = "ffee70a111fd07372982b0550bbb14b7"
|
|
SRC_URI[sha256sum] = "9b635e60feb163e6fc6c375721f71f44d7e26d6b9cd52f6b86b04e65d2481cbc"
|
|
|
|
inherit autotools lib_package binconfig multilib_header
|
|
|
|
OE_BINCONFIG_EXTRA_MANGLE = " -e 's:location=source:location=installed:'"
|
|
|
|
do_configure_prepend() {
|
|
cd ${S}
|
|
./buildconf
|
|
}
|
|
|
|
FILES_${PN}-dev += "${libdir}/apr.exp ${datadir}/build-1/*"
|
|
|
|
#for some reason, build/libtool.m4 handled by buildconf still be overwritten
|
|
#when autoconf, so handle it again.
|
|
do_configure_append() {
|
|
cd ${S}
|
|
sed -i -e 's/LIBTOOL=\(.*\)top_build/LIBTOOL=\1apr_build/' build/libtool.m4
|
|
sed -i -e 's/LIBTOOL=\(.*\)top_build/LIBTOOL=\1apr_build/' build/apr_rules.mk
|
|
}
|
|
|
|
do_install_append() {
|
|
oe_multilib_header apr.h
|
|
install -d ${D}${datadir}/apr
|
|
cp ${S}/${HOST_SYS}-libtool ${D}${datadir}/build-1/libtool
|
|
}
|
|
|
|
SSTATE_SCAN_FILES += "apr_rules.mk"
|
|
|
|
SYSROOT_PREPROCESS_FUNCS += "apr_sysroot_preprocess"
|
|
|
|
apr_sysroot_preprocess () {
|
|
d=${SYSROOT_DESTDIR}${datadir}/apr
|
|
install -d $d/
|
|
cp ${S}/build/apr_rules.mk $d/
|
|
sed -i s,apr_builddir=.*,apr_builddir=,g $d/apr_rules.mk
|
|
sed -i s,apr_builders=.*,apr_builders=,g $d/apr_rules.mk
|
|
sed -i s,LIBTOOL=.*,LIBTOOL=\$\(SHELL\)\ ${HOST_SYS}-libtool,g $d/apr_rules.mk
|
|
sed -i s,\$\(apr_builders\),${STAGING_DATADIR}/apr/,g $d/apr_rules.mk
|
|
cp ${S}/build/mkdir.sh $d/
|
|
cp ${S}/build/make_exports.awk $d/
|
|
cp ${S}/build/make_var_export.awk $d/
|
|
}
|