mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 03:32:13 +02:00
18e3554301
0001-btrfs-tools-include-linux-const.h-to-fix-build-with-.patch removed since it is included in 5.16 Add 0001-btrfs-progs-kerncompat-add-local-definition-for-alig.patch to fix "undefined reference to `__ALIGN_KERNEL'". Changelog: ========= - rescue: new subcommand clear-uuid-tree to fix failed mount due to bad uuid subvolume keys, caught by tree-checker - fi du: skip inaccessible files - prop: properly resolve to symlink targets - send, receive: fix crash after parent subvolume lookup errors - build: fix build on 5.12+ kernels due to changes in linux/kernel.h fix build on musl with old kernel headers - other: error handling fixes, cleanups, refactoring extent tree v2 preparatory work lots of RST documentation updates (last release with asciidoc sources), https://btrfs.readthedocs.io (From OE-Core rev: 420191dc951f04b36645ffae2d946b50150feab0) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
73 lines
2.8 KiB
BlitzBasic
73 lines
2.8 KiB
BlitzBasic
SUMMARY = "Checksumming Copy on Write Filesystem utilities"
|
|
DESCRIPTION = "Btrfs is a new copy on write filesystem for Linux aimed at \
|
|
implementing advanced features while focusing on fault tolerance, repair and \
|
|
easy administration. \
|
|
This package contains utilities (mkfs, fsck, btrfsctl) used to work with \
|
|
btrfs and an utility (btrfs-convert) to make a btrfs filesystem from an ext3."
|
|
|
|
HOMEPAGE = "https://btrfs.wiki.kernel.org"
|
|
|
|
LICENSE = "GPLv2 & LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://COPYING;md5=fcb02dc552a041dee27e4b85c7396067 \
|
|
file://libbtrfsutil/COPYING;md5=4fbd65380cdd255951079008b364516c \
|
|
"
|
|
SECTION = "base"
|
|
DEPENDS = "lzo util-linux zlib"
|
|
|
|
SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/kdave/btrfs-progs.git;branch=master \
|
|
file://0001-Add-a-possibility-to-specify-where-python-modules-ar.patch \
|
|
file://0001-btrfs-progs-kerncompat-add-local-definition-for-alig.patch \
|
|
"
|
|
SRCREV = "8ad326b2f28c044cb6ed9016d7c3285e23b673c8"
|
|
S = "${WORKDIR}/git"
|
|
|
|
PACKAGECONFIG ??= " \
|
|
programs \
|
|
convert \
|
|
python \
|
|
crypto-builtin \
|
|
"
|
|
PACKAGECONFIG[manpages] = "--enable-documentation, --disable-documentation, asciidoc-native xmlto-native"
|
|
PACKAGECONFIG[programs] = "--enable-programs,--disable-programs"
|
|
PACKAGECONFIG[convert] = "--enable-convert --with-convert=ext2,--disable-convert --without-convert,e2fsprogs"
|
|
PACKAGECONFIG[zoned] = "--enable-zoned,--disable-zoned"
|
|
PACKAGECONFIG[python] = "--enable-python,--disable-python,python3-setuptools-native"
|
|
PACKAGECONFIG[zstd] = "--enable-zstd,--disable-zstd,zstd"
|
|
PACKAGECONFIG[udev] = "--enable-libudev,--disable-libudev,udev"
|
|
|
|
# Pick only one crypto provider
|
|
PACKAGECONFIG[crypto-builtin] = "--with-crypto=builtin"
|
|
PACKAGECONFIG[crypto-libgcrypt] = "--with-crypto=libgcrypt,,libgcrypt"
|
|
PACKAGECONFIG[crypto-libsodium] = "--with-crypto=libsodium,,libsodium"
|
|
PACKAGECONFIG[crypto-libkcapi] = "--with-crypto=libkcapi,,libkcapi"
|
|
|
|
inherit autotools-brokensep pkgconfig manpages
|
|
inherit ${@bb.utils.contains('PACKAGECONFIG', 'python', 'setuptools3-base', '', d)}
|
|
|
|
CLEANBROKEN = "1"
|
|
|
|
EXTRA_OECONF = "--enable-largefile"
|
|
EXTRA_OECONF:append:libc-musl = " --disable-backtrace "
|
|
EXTRA_PYTHON_CFLAGS = "${DEBUG_PREFIX_MAP}"
|
|
EXTRA_PYTHON_CFLAGS:class-native = ""
|
|
EXTRA_PYTHON_LDFLAGS = "${LDFLAGS}"
|
|
EXTRA_OEMAKE = "V=1 'EXTRA_PYTHON_CFLAGS=${EXTRA_PYTHON_CFLAGS}' 'EXTRA_PYTHON_LDFLAGS=${EXTRA_PYTHON_LDFLAGS}'"
|
|
|
|
do_configure:prepend() {
|
|
# Upstream doesn't ship this and autoreconf won't install it as automake isn't used.
|
|
mkdir -p ${S}/config
|
|
cp -f $(automake --print-libdir)/install-sh ${S}/config/
|
|
}
|
|
|
|
|
|
do_install:append() {
|
|
if [ "${@bb.utils.filter('PACKAGECONFIG', 'python', d)}" ]; then
|
|
oe_runmake 'DESTDIR=${D}' 'PYTHON_SITEPACKAGES_DIR=${PYTHON_SITEPACKAGES_DIR}' install_python
|
|
fi
|
|
}
|
|
|
|
RDEPENDS:${PN} = "libgcc"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|