mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
a2f9d0c4bf
When IPv6 support is disabled, this recipe mis-configures ruby so that it end up non-working: --enable-wide-getaddrinfo instructs ruby to re-implement the standard getaddinfo(), but IPv6 support is still automatically detected via ext/socket/extconf.rb independently of that flag. To re-implement getaddrinfo(), ruby uses the obsolete getipnodebyaddr() and getipnodebyname() functions - i.e. according to the man-page, glibc provided those only in glibc 2.1.91-95; and of course compilation fails. [1] Switch to ruby's standard --enable-ipv6= configure options to make the build work without warnings, and ruby work at runtime as well. [1] Compilation and linking actually succeed, albeit with a warning regarding implicit declaration / unresolved symbols. The error is only obvious at runtime due to the unresolved symbols... (From OE-Core rev: 6ff71dd308b1611df7a8ea811a79b7cb884c99e9) Signed-off-by: André Draszik <andre.draszik@jci.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
75 lines
2.3 KiB
BlitzBasic
75 lines
2.3 KiB
BlitzBasic
require ruby.inc
|
|
|
|
SRC_URI += " \
|
|
file://0001-configure.ac-check-finite-isinf-isnan-as-macros-firs.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "7e156fb526b8f4bb1b30a3dd8a7ce400"
|
|
SRC_URI[sha256sum] = "28a945fdf340e6ba04fc890b98648342e3cccfd6d223a48f3810572f11b2514c"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG += "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
|
|
|
|
PACKAGECONFIG[valgrind] = "--with-valgrind=yes, --with-valgrind=no, valgrind"
|
|
PACKAGECONFIG[gmp] = "--with-gmp=yes, --with-gmp=no, gmp"
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6, --disable-ipv6,"
|
|
|
|
EXTRA_AUTORECONF += "--exclude=aclocal"
|
|
|
|
EXTRA_OECONF = "\
|
|
--disable-versioned-paths \
|
|
--disable-rpath \
|
|
--disable-dtrace \
|
|
--enable-shared \
|
|
--enable-load-relative \
|
|
--with-pkg-config=pkg-config \
|
|
"
|
|
|
|
do_install() {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
}
|
|
|
|
do_install_append_class-target () {
|
|
# Find out rbconfig.rb from .installed.list
|
|
rbconfig_rb=`grep rbconfig.rb ${B}/.installed.list`
|
|
# Remove build host directories
|
|
sed -i -e 's:--sysroot=${STAGING_DIR_TARGET}::g' \
|
|
-e s:'--with-libtool-sysroot=${STAGING_DIR_TARGET}'::g \
|
|
-e 's|${DEBUG_PREFIX_MAP}||g' \
|
|
-e 's:${HOSTTOOLS_DIR}/::g' \
|
|
-e 's:${RECIPE_SYSROOT_NATIVE}::g' \
|
|
-e 's:${RECIPE_SYSROOT}::g' \
|
|
-e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
|
|
${D}$rbconfig_rb
|
|
|
|
# Find out created.rid from .installed.list
|
|
created_rid=`grep created.rid ${B}/.installed.list`
|
|
# Remove build host directories
|
|
sed -i -e 's:${WORKDIR}::g' ${D}$created_rid
|
|
|
|
}
|
|
|
|
do_install_ptest () {
|
|
cp -rf ${S}/test ${D}${PTEST_PATH}/
|
|
cp -r ${S}/include ${D}/${libdir}/ruby/
|
|
test_case_rb=`grep rubygems/test_case.rb ${B}/.installed.list`
|
|
sed -i -e 's:../../../test/:../../../ptest/test/:g' ${D}/$test_case_rb
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-ri-docs ${PN}-rdoc"
|
|
|
|
SUMMARY_${PN}-ri-docs = "ri (Ruby Interactive) documentation for the Ruby standard library"
|
|
RDEPENDS_${PN}-ri-docs = "${PN}"
|
|
FILES_${PN}-ri-docs += "${datadir}/ri"
|
|
|
|
SUMMARY_${PN}-rdoc = "RDoc documentation generator from Ruby source"
|
|
RDEPENDS_${PN}-rdoc = "${PN}"
|
|
FILES_${PN}-rdoc += "${libdir}/ruby/*/rdoc ${bindir}/rdoc"
|
|
|
|
FILES_${PN} += "${datadir}/rubygems"
|
|
|
|
FILES_${PN}-ptest_append_class-target += "${libdir}/ruby/include"
|
|
|
|
BBCLASSEXTEND = "native"
|