mirror of
https://git.yoctoproject.org/poky
synced 2026-03-05 23:09:39 +01:00
87d51bd79b
41d8236 Set GDB version number to 7.11.1. 136613e Fix PR gdb/19828: gdb -p <process from a container>: internal error a0de87e Make gdb/linux-nat.c consider a waitstatus pending on the infrun side cf2cd51 Add mi-threads-interrupt.exp test (PR 20039) f0a8d0d Fix double prompt output after run control MI commands with mi-async on (PR 20045) b5f0db4 Fix -exec-run not running asynchronously with mi-async on (PR gdb/18077) 7f8e34d Use target_terminal_ours_for_output in MI (From OE-Core rev: 371345c0dc49bf781c27aea1e9f6a4c947fa30e6) (From OE-Core rev: 23a7c411b39eece9c80e1fde84894c75ca8dcbe0) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
66 lines
2.2 KiB
PHP
66 lines
2.2 KiB
PHP
SUMMARY = "GNU debugger"
|
|
HOMEPAGE = "http://www.gnu.org/software/gdb/"
|
|
SECTION = "devel"
|
|
DEPENDS = "expat zlib ncurses virtual/libiconv ${LTTNGUST}"
|
|
|
|
LTTNGUST = "lttng-ust"
|
|
LTTNGUST_aarch64 = ""
|
|
LTTNGUST_libc-uclibc = ""
|
|
LTTNGUST_mips = ""
|
|
LTTNGUST_mipsel = ""
|
|
LTTNGUST_mips64 = ""
|
|
LTTNGUST_mips64el = ""
|
|
LTTNGUST_mips64n32 = ""
|
|
LTTNGUST_mips64eln32 = ""
|
|
LTTNGUST_sh4 = ""
|
|
LTTNGUST_libc-musl = ""
|
|
|
|
inherit autotools texinfo
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "gdb\-(?P<pver>.+)\-release"
|
|
|
|
B = "${WORKDIR}/build-${TARGET_SYS}"
|
|
|
|
EXTRA_OEMAKE = "'SUBDIRS=intl mmalloc libiberty opcodes bfd sim gdb etc utils'"
|
|
|
|
EXPAT = "--with-expat --with-libexpat-prefix=${STAGING_DIR_HOST}"
|
|
|
|
EXTRA_OECONF = "--disable-gdbtk --disable-tui --disable-x --disable-werror \
|
|
--with-curses --disable-multilib --disable-sim \
|
|
--without-lzma --without-guile \
|
|
${GDBPROPREFIX} ${EXPAT} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'multiarch', '--enable-64-bit-bfd', '', d)} \
|
|
--disable-rpath \
|
|
--disable-gas --disable-binutils \
|
|
--disable-ld --disable-gold \
|
|
--disable-gprof \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "readline"
|
|
# Use --without-system-readline to compile with readline 5.
|
|
PACKAGECONFIG[readline] = "--with-system-readline,--without-system-readline,readline"
|
|
PACKAGECONFIG[python] = "--with-python=${WORKDIR}/python,--without-python,python3,python3 python3-codecs"
|
|
PACKAGECONFIG[babeltrace] = "--with-babeltrace,--without-babeltrace,babeltrace"
|
|
|
|
GDBPROPREFIX = "--program-prefix=''"
|
|
|
|
do_configure () {
|
|
# override this function to avoid the autoconf/automake/aclocal/autoheader
|
|
# calls for now
|
|
(cd ${S} && gnu-configize) || die "failure in running gnu-configize"
|
|
oe_runconf
|
|
}
|
|
|
|
# we don't want gdb to provide bfd/iberty/opcodes, which instead will override the
|
|
# right bits installed by binutils.
|
|
do_install_append() {
|
|
rm -rf ${D}${libdir}
|
|
rm -rf ${D}${includedir}
|
|
rm -rf ${D}${datadir}/locale
|
|
}
|
|
|
|
RRECOMMENDS_gdb_append_linux = " glibc-thread-db "
|
|
RRECOMMENDS_gdb_append_linux-gnueabi = " glibc-thread-db "
|
|
RRECOMMENDS_gdbserver_append_linux = " glibc-thread-db "
|
|
RRECOMMENDS_gdbserver_append_linux-gnueabi = " glibc-thread-db "
|