mirror of
https://git.yoctoproject.org/poky
synced 2026-02-27 03:49:41 +01:00
5ddf8570a1
The overrides virtclass-native and virtclass-nativesdk are deprecated, which should be replaced by class-native and class-nativesdk. NOTE: There were 2 errors in libcap.inc, the BUILD_LDFLAGS_virtclass_native should be BUILD_LDFLAGS_virtclass-native (the "_" should be "-"), otherwise it doesn't work, and the value was: "-Wl,rpath=...", this is incorrect, it shoudl be: "-Wl,-rpath=..." (lacked a - ), but we don't need this line, since it is already in the default BUILD_LDFLAGS. Remove it and we don't need to bump the PR since we just removed a unused line. [YOCTO #3297] (From OE-Core rev: cafb550fe9034754933f1708446dde155dcc3d51) Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
63 lines
1.6 KiB
PHP
63 lines
1.6 KiB
PHP
DESCRIPTION = "support for getting/setting POSIX.1e capabilities"
|
|
HOMEPAGE = "http://sites.google.com/site/fullycapable/"
|
|
|
|
# no specific GPL version required
|
|
LICENSE = "BSD | GPLv2"
|
|
LIC_FILES_CHKSUM = "file://License;md5=3f84fd6f29d453a56514cb7e4ead25f1"
|
|
|
|
DEPENDS = "attr perl-native-runtime"
|
|
DEPENDS += "${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
# attr and pam are disabled by EXTRA_OEMAKE_class-native
|
|
DEPENDS_class-native = "perl-native-runtime"
|
|
|
|
SRC_URI = "${DEBIAN_MIRROR}/main/libc/libcap2/${BPN}2_${PV}.orig.tar.gz"
|
|
|
|
PR = "r1"
|
|
|
|
inherit lib_package
|
|
|
|
do_configure() {
|
|
# libcap uses := for compilers, fortunately, it gives us a hint
|
|
# on what should be replaced with ?=
|
|
sed -e 's,:=,?=,g' -i Make.Rules
|
|
sed -e 's,BUILD_CFLAGS ?=,BUILD_CFLAGS := $(BUILD_CFLAGS),' -i Make.Rules
|
|
}
|
|
|
|
EXTRA_OEMAKE = " \
|
|
LIBATTR=yes \
|
|
PAM_CAP=${@base_contains('DISTRO_FEATURES', 'pam', 'yes', 'no', d)} \
|
|
INDENT= SYSTEM_HEADERS=${STAGING_INCDIR} RAISE_SETFCAP=no \
|
|
lib=${@os.path.basename('${libdir}')} \
|
|
"
|
|
EXTRA_OEMAKE_class-native = " \
|
|
LIBATTR=no \
|
|
PAM_CAP=no \
|
|
INDENT= \
|
|
lib=${@os.path.basename('${libdir}')} \
|
|
"
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR="${D}" prefix="${prefix}" SBINDIR="${D}${sbindir}"
|
|
}
|
|
|
|
do_install_append() {
|
|
# Move the library to base_libdir
|
|
install -d ${D}${base_libdir}
|
|
if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then
|
|
mv ${D}${libdir}/* ${D}${base_libdir}
|
|
rmdir ${D}${libdir}
|
|
fi
|
|
}
|
|
|
|
FILES_${PN}-dev += "${base_libdir}/*.so"
|
|
|
|
# pam files
|
|
FILES_${PN} += "${base_libdir}/security/*.so"
|
|
FILES_${PN}-dbg += "${base_libdir}/security/.debug/*.so"
|
|
|
|
BBCLASSEXTEND = "native"
|