mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 00:32:14 +02:00
87af2a9001
It fails to install sudo and lib32-sudo at same time:
| Error: Transaction test error:
| file /usr/libexec/sudo/audit_json.so conflicts between attempted
installs of lib32-sudo-1.9.3p1-r0.core2_32 and sudo-1.9.3p1-r0.core2_64
| file /usr/libexec/sudo/group_file.so conflicts between attempted
installs of lib32-sudo-1.9.3p1-r0.core2_32 and sudo-1.9.3p1-r0.core2_64
Pass ${libdir} to configure option --libexecdir of sudo that it installs
plugin libraries to /usr/lib{,64} rather than /usr/libexec/. Then add a
patch to fix multilib conflict of sudo.conf.
[RP: Add missing Upstream-Status]
(From OE-Core rev: 9d67dd5a6363b9fae10784e8056e469ba2ef5735)
Signed-off-by: Kai Kang <kai.kang@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
(cherry picked from commit c9b6974cfcac370c6848d28400e0546ac85512e9)
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
2.0 KiB
BlitzBasic
50 lines
2.0 KiB
BlitzBasic
require sudo.inc
|
|
|
|
SRC_URI = "https://www.sudo.ws/dist/sudo-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)} \
|
|
file://0001-sudo.conf.in-fix-conflict-with-multilib.patch \
|
|
"
|
|
|
|
PAM_SRC_URI = "file://sudo.pam"
|
|
|
|
SRC_URI[sha256sum] = "1d9889cc3b3b15ed8c2c7c3de3aa392a3a726838d020815067c080525c3f5837"
|
|
|
|
DEPENDS += " virtual/crypt ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS_${PN} += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam-plugin-limits pam-plugin-keyinit', '', d)}"
|
|
|
|
CACHED_CONFIGUREVARS = " \
|
|
ac_cv_type_rsize_t=no \
|
|
ac_cv_path_MVPROG=${base_bindir}/mv \
|
|
ac_cv_path_BSHELLPROG=${base_bindir}/sh \
|
|
ac_cv_path_SENDMAILPROG=${sbindir}/sendmail \
|
|
ac_cv_path_VIPROG=${base_bindir}/vi \
|
|
"
|
|
|
|
EXTRA_OECONF += " \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-tmpfiles.d=${nonarch_libdir}/tmpfiles.d', '--disable-tmpfiles.d', d)} \
|
|
--with-rundir=/run/sudo \
|
|
--with-vardir=/var/lib/sudo \
|
|
--libexecdir=${libdir} \
|
|
"
|
|
|
|
do_install_append () {
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" ]; then
|
|
install -D -m 644 ${WORKDIR}/sudo.pam ${D}/${sysconfdir}/pam.d/sudo
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'pam-wheel', 'true', 'false', d)} ; then
|
|
echo 'auth required pam_wheel.so use_uid' >>${D}${sysconfdir}/pam.d/sudo
|
|
sed -i 's/# \(%wheel ALL=(ALL) ALL\)/\1/' ${D}${sysconfdir}/sudoers
|
|
fi
|
|
fi
|
|
|
|
chmod 4111 ${D}${bindir}/sudo
|
|
chmod 0440 ${D}${sysconfdir}/sudoers
|
|
|
|
# Explicitly remove the /sudo directory to avoid QA error
|
|
rmdir -p --ignore-fail-on-non-empty ${D}/run/sudo
|
|
}
|
|
|
|
FILES_${PN} += "${nonarch_libdir}/tmpfiles.d"
|
|
FILES_${PN}-dev += "${libdir}/${BPN}/lib*${SOLIBSDEV} ${libdir}/${BPN}/*.la \
|
|
${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la"
|