mirror of
https://git.yoctoproject.org/poky
synced 2026-02-14 04:33:03 +01:00
a5f82b4ddb
87152c0 : Update to 0.29.1 753f0ba : glib: Fix OSX build with internal glib 5164b9d : Revert "Quote pc_path virtual variable" a3e58e7 : check: More thoroughly test variable usage 1c564a3 : Only unquote --variable when it appears quoted e6d33fb : Revert "Unquote values of requested variables" 8d19fad : Also match -Wl,-framework for OSX framework ae0a8b1 : Allow overriding package variables with env vars 9ef2d34 : Pass key into parse_package_key so it can be set early 52baea8 : README.win32: Add info on building with MSVC 5f70074 : build: Add NMake makefiles for Visual Studio builds 1ed3367 : build: Add a pre-configure config.h template for MSVC builds 56061ef : build: Split Out Source Listing dd57ff3 : pkg.c: Port from dirent to GDir (From OE-Core rev: 8f83f09aaa3dc67af44edba2084378f1835ae322) Signed-off-by: Maxin B. John <maxin.john@intel.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
1.9 KiB
BlitzBasic
54 lines
1.9 KiB
BlitzBasic
SUMMARY = "Helper tool used when compiling"
|
|
DESCRIPTION = "pkg-config is a helper tool used when compiling applications and libraries. It helps determined \
|
|
the correct compiler/link options. It is also language-agnostic."
|
|
HOMEPAGE = "http://pkg-config.freedesktop.org/wiki/"
|
|
BUGTRACKER = "http://bugs.freedesktop.org/buglist.cgi?product=pkg-config"
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = "glib-2.0"
|
|
DEPENDS_class-native = ""
|
|
DEPENDS_class-nativesdk = ""
|
|
|
|
SRCREV = "87152c05be88ca8be71a3a563f275b3686d32c28"
|
|
PV = "0.29.1+git${SRCPV}"
|
|
|
|
SRC_URI = "git://anongit.freedesktop.org/pkg-config \
|
|
file://pkg-config-native.in \
|
|
file://fix-glib-configure-libtool-usage.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools
|
|
|
|
EXTRA_OECONF = "--without-internal-glib"
|
|
EXTRA_OECONF_class-native = "--with-internal-glib"
|
|
EXTRA_OECONF_class-nativesdk = "--with-internal-glib"
|
|
|
|
acpaths = "-I ."
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# Set an empty dev package to ensure the base PN package gets
|
|
# the pkg.m4 macros, pkgconfig does not deliver any other -dev
|
|
# files.
|
|
FILES_${PN}-dev = ""
|
|
FILES_${PN} += "${datadir}/aclocal/pkg.m4"
|
|
|
|
# When using the RPM generated automatic package dependencies, some packages
|
|
# will end up requiring 'pkgconfig(pkg-config)'. Allow this behavior by
|
|
# specifying an appropriate provide.
|
|
RPROVIDES_${PN} += "pkgconfig(pkg-config)"
|
|
|
|
# Install a pkg-config-native wrapper that will use the native sysroot instead
|
|
# of the MACHINE sysroot, for using pkg-config when building native tools.
|
|
do_install_append_class-native () {
|
|
sed -e "s|@PATH_NATIVE@|${PKG_CONFIG_PATH}|" \
|
|
-e "s|@LIBDIR_NATIVE@|${PKG_CONFIG_LIBDIR}|" \
|
|
< ${WORKDIR}/pkg-config-native.in > ${B}/pkg-config-native
|
|
install -m755 ${B}/pkg-config-native ${D}${bindir}/pkg-config-native
|
|
}
|