mirror of
https://git.yoctoproject.org/poky
synced 2026-03-04 06:19:40 +01:00
7e98e4d55c
Minor upgrade on 3.5 release series (From OE-Core rev: da9b363acea2545721702fc7c39c4589b666c61b) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.5 KiB
BlitzBasic
41 lines
1.5 KiB
BlitzBasic
SUMMARY = "GNU Project parser generator (yacc replacement)"
|
|
DESCRIPTION = "Bison is a general-purpose parser generator that converts an annotated context-free grammar into \
|
|
an LALR(1) or GLR parser for that grammar. Bison is upward compatible with Yacc: all properly-written Yacc \
|
|
grammars ought to work with Bison with no change. Anyone familiar with Yacc should be able to use Bison with \
|
|
little trouble."
|
|
HOMEPAGE = "http://www.gnu.org/software/bison/"
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
SECTION = "devel"
|
|
DEPENDS = "bison-native flex-native"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/bison/bison-${PV}.tar.xz \
|
|
file://dont-depend-on-help2man.patch.patch \
|
|
file://add-with-bisonlocaledir.patch \
|
|
"
|
|
|
|
# No point in hardcoding path to m4, just use PATH
|
|
EXTRA_OECONF += "M4=m4"
|
|
|
|
SRC_URI[md5sum] = "6fc5fa4488832a65db934b9e93bd5d4c"
|
|
SRC_URI[sha256sum] = "3e7e097bd9709a2d5e40e69446b74b149733b3de864fadb7a9b54eca7b2a4dd0"
|
|
|
|
inherit autotools gettext texinfo
|
|
|
|
# The automatic m4 path detection gets confused, so force the right value
|
|
acpaths = "-I ${S}/m4"
|
|
|
|
do_compile_prepend() {
|
|
for i in mfcalc calc++ rpcalc; do mkdir -p ${B}/examples/$i; done
|
|
}
|
|
|
|
do_install_append_class-native() {
|
|
create_wrapper ${D}/${bindir}/bison \
|
|
BISON_PKGDATADIR=${STAGING_DATADIR_NATIVE}/bison
|
|
}
|
|
do_install_append_class-nativesdk() {
|
|
create_wrapper ${D}/${bindir}/bison \
|
|
BISON_PKGDATADIR=${datadir}/bison
|
|
}
|
|
BBCLASSEXTEND = "native nativesdk"
|