mirror of
https://git.yoctoproject.org/poky
synced 2026-03-05 06:49:39 +01:00
d4aa199836
Add default values for go environment variables to go-common.inc. Override where appropriate in other go*.inc files, and use host/target tuples from goarch for setting CC flags. (From OE-Core rev: 1e3f040b1f68fa1f808851ecd9623544e935e9ad) Signed-off-by: Alex Kube <alexander.j.kube@gmail.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.4 KiB
PHP
46 lines
1.4 KiB
PHP
DEPENDS = "virtual/${TUNE_PKGARCH}-go go-native"
|
|
DEPENDS_class-nativesdk = "virtual/${TARGET_PREFIX}go-crosssdk go-native"
|
|
|
|
export GOCACHE = "${B}/.cache"
|
|
GO_LDFLAGS = ""
|
|
GO_LDFLAGS_class-nativesdk = "-linkmode external"
|
|
export GO_LDFLAGS
|
|
|
|
CC_append_class-nativesdk = " ${SECURITY_NOPIE_CFLAGS}"
|
|
|
|
do_configure[noexec] = "1"
|
|
|
|
do_compile() {
|
|
export CC_FOR_${TARGET_GOOS}_${TARGET_GOARCH}="${CC}"
|
|
export CXX_FOR_${TARGET_GOOS}_${TARGET_GOARCH}="${CXX}"
|
|
|
|
cd src
|
|
./make.bash --target-only --no-banner
|
|
cd ${B}
|
|
}
|
|
do_compile[dirs] =+ "${GOTMPDIR} ${B}/bin ${B}/pkg"
|
|
do_compile[cleandirs] += "${GOTMPDIR} ${B}/bin ${B}/pkg"
|
|
|
|
do_install() {
|
|
install -d ${D}${libdir}/go/pkg/tool
|
|
cp --preserve=mode,timestamps -R ${B}/pkg/tool/${TARGET_GOTUPLE} ${D}${libdir}/go/pkg/tool/
|
|
install -d ${D}${libdir}/go/src
|
|
cp --preserve=mode,timestamps -R ${S}/src/cmd ${D}${libdir}/go/src/
|
|
find ${D}${libdir}/go/src -depth -type d -name testdata -exec rm -rf {} \;
|
|
install -d ${D}${libdir}/go/bin
|
|
install -d ${D}${bindir}
|
|
for f in ${B}/${GO_BUILD_BINDIR}/*; do
|
|
name=`basename $f`
|
|
install -m 0755 $f ${D}${libdir}/go/bin/
|
|
ln -sf ../${baselib}/go/bin/$name ${D}${bindir}/
|
|
done
|
|
}
|
|
|
|
PACKAGES = "${PN} ${PN}-dev"
|
|
FILES_${PN} = "${libdir}/go/bin ${libdir}/go/pkg/tool/${TARGET_GOTUPLE} ${bindir}"
|
|
FILES_${PN}-dev = "${libdir}/go"
|
|
RDEPENDS_${PN}-dev = "perl bash"
|
|
INSANE_SKIP_${PN} = "ldflags"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|