mirror of
https://git.yoctoproject.org/poky
synced 2026-05-04 13:39:49 +02:00
ad23395cd1
As discussed on the mailing lists, using a suffix to package names is hard and has lead to many recipes having to do PKGSUFFIX games. Its looking extremely hard to scale nativesdk much further without hacking many recipes. By comparison, using a prefix like multilib does works much better and doesn't involve "hacking" as many recipes. This change converts nativesdk to use a prefix using the existing multilib infrastructure. (From OE-Core rev: 81813c0e322dc04ce4b069117188d8a54dfddb8c) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
81 lines
2.9 KiB
PHP
81 lines
2.9 KiB
PHP
DESCRIPTION = "Open Package Manager"
|
|
DESCRIPTION_libopkg = "Open Package Manager Library"
|
|
DESCRIPTION_update-alternatives-cworth = "Update alternatives"
|
|
SECTION = "base"
|
|
HOMEPAGE = "http://code.google.com/p/opkg/"
|
|
BUGTRACKER = "http://code.google.com/p/opkg/issues/list"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://src/opkg-cl.c;beginline=1;endline=20;md5=321f658c3f6b6c832e25c8850b5dffba"
|
|
DEPENDS_virtclass-native = "curl-native"
|
|
DEPENDS_virtclass-nativesdk = "nativesdk-curl"
|
|
|
|
PE = "1"
|
|
INC_PR = "r10"
|
|
|
|
FILESDIR = "${@os.path.dirname(d.getVar('FILE',1))}/opkg"
|
|
|
|
# Werror gives all kinds bounds issuses with gcc 4.3.3
|
|
do_configure_prepend() {
|
|
sed -i -e s:-Werror::g ${S}/libopkg/Makefile.am
|
|
}
|
|
|
|
inherit autotools pkgconfig
|
|
EXTRA_OECONF += " --disable-gpg \
|
|
--disable-openssl \
|
|
--disable-ssl-curl \
|
|
--disable-curl \
|
|
--disable-sha256"
|
|
|
|
target_localstatedir := "${localstatedir}"
|
|
EXTRA_OECONF += "--with-opkglibdir=${localstatedir}/lib"
|
|
EXTRA_OECONF_virtclass-native = "--with-opkglibdir=${target_localstatedir}/lib --disable-gpg --disable-curl --disable-openssl"
|
|
EXTRA_OECONF_virtclass-nativesdk = "--with-opkglibdir=${target_localstatedir}/lib --disable-gpg --disable-curl --disable-openssl"
|
|
|
|
PROVIDES += "virtual/update-alternatives"
|
|
RPROVIDES_update-alternatives-cworth += "update-alternatives"
|
|
RCONFLICTS_update-alternatives-cworth = "update-alternatives-dpkg"
|
|
RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-config-base"
|
|
RDEPENDS_${PN}_virtclass-native = ""
|
|
RDEPENDS_${PN}_virtclass-nativesdk = ""
|
|
PACKAGE_ARCH_update-alternatives-cworth = "all"
|
|
RREPLACES_${PN} = "opkg-nogpg"
|
|
|
|
PACKAGES =+ "libopkg-dev libopkg-staticdev libopkg update-alternatives-cworth"
|
|
|
|
FILES_update-alternatives-cworth = "${bindir}/update-alternatives"
|
|
FILES_libopkg-dev = "${libdir}/*.la ${libdir}/*.so"
|
|
FILES_libopkg-staticdev = "${libdir}/*.a"
|
|
FILES_libopkg = "${libdir}/*.so.* ${localstatedir}/lib/opkg/"
|
|
|
|
# We need to create the lock directory
|
|
do_install_append() {
|
|
install -d ${D}${localstatedir}/lib/opkg
|
|
}
|
|
|
|
pkg_postinst_${PN} () {
|
|
#!/bin/sh
|
|
if [ "x$D" != "x" ]; then
|
|
install -d $D${sysconfdir}/rcS.d
|
|
# this happens at S98 where our good 'ole packages script used to run
|
|
echo "#!/bin/sh
|
|
opkg-cl configure
|
|
rm -f /${sysconfdir}/rcS.d/S${POSTINSTALL_INITPOSITION}run-postinsts
|
|
" > $D${sysconfdir}/rcS.d/S${POSTINSTALL_INITPOSITION}run-postinsts
|
|
chmod 0755 $D${sysconfdir}/rcS.d/S${POSTINSTALL_INITPOSITION}run-postinsts
|
|
fi
|
|
}
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
ALTERNATIVE_${PN} = "opkg"
|
|
ALTERNATIVE_LINK_NAME[opkg] = "${bindir}/opkg"
|
|
ALTERNATIVE_TARGET[opkg] = "${bindir}/opkg-cl"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
# Define a variable to allow distros to run configure earlier.
|
|
# (for example, to enable loading of ethernet kernel modules before networking starts)
|
|
POSTINSTALL_INITPOSITION ?= "98"
|