mirror of
https://git.yoctoproject.org/poky
synced 2026-09-24 22:36:21 +02:00
eba0e64a88
The tarball (neard-0.16.tar.xz) fetched by the recipe is incomplete. Few plugins (e.g. tizen) and tests scripts (e.g. Test-channel, test-see, neard-ui.py, ndef-agent etc) are missing. Since neard did not release latest tarballs, so as per community recommendation switching the recipe SRC_URI to git repo. Community Discussion: https://lists.openembedded.org/g/openembedded-core/topic/90058043#163681 (From OE-Core rev: d836d47f6a8659f84f2e8e755035392b994fd1fb) Signed-off-by: Rahul Kumar <rahul.kumar_3@philips.com> Signed-off-by: Luca Ceresoli <luca.ceresoli@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry-picked from b563f40ebf4461d9c35df72bd7599ea11e97da9c) Signed-off-by: Rahul Kumar <rahul.kumar_3@philips.com> Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
52 lines
1.8 KiB
BlitzBasic
52 lines
1.8 KiB
BlitzBasic
SUMMARY = "Linux NFC daemon"
|
|
DESCRIPTION = "A daemon for the Linux Near Field Communication stack"
|
|
HOMEPAGE = "http://01.org/linux-nfc"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
|
|
file://src/near.h;beginline=1;endline=20;md5=358e4deefef251a4761e1ffacc965d13 \
|
|
"
|
|
|
|
DEPENDS = "dbus glib-2.0 libnl"
|
|
|
|
SRC_URI = "git://git.kernel.org/pub/scm/network/nfc/neard.git;protocol=git;branch=master \
|
|
file://neard.in \
|
|
file://Makefile.am-fix-parallel-issue.patch \
|
|
file://Makefile.am-do-not-ship-version.h.patch \
|
|
file://0001-Add-header-dependency-to-nciattach.o.patch \
|
|
"
|
|
|
|
SRCREV = "949795024f7625420e93e288c56e194cb9a3e74a"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools pkgconfig systemd update-rc.d
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
|
|
|
|
PACKAGECONFIG[systemd] = "--enable-systemd --with-systemdsystemunitdir=${systemd_unitdir}/system/ --with-systemduserunitdir=${systemd_unitdir}/user/,--disable-systemd"
|
|
|
|
EXTRA_OECONF += "--enable-tools"
|
|
|
|
# This would copy neard start-stop shell and test scripts
|
|
do_install_append() {
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
|
|
install -d ${D}${sysconfdir}/init.d/
|
|
sed "s:@installpath@:${libexecdir}/nfc:" ${WORKDIR}/neard.in \
|
|
> ${D}${sysconfdir}/init.d/neard
|
|
chmod 0755 ${D}${sysconfdir}/init.d/neard
|
|
fi
|
|
}
|
|
|
|
RDEPENDS_${PN} = "dbus"
|
|
|
|
# Bluez & Wifi are not mandatory except for handover
|
|
RRECOMMENDS_${PN} = "\
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez5', '', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'wifi','wpa-supplicant', '', d)} \
|
|
"
|
|
|
|
INITSCRIPT_NAME = "neard"
|
|
INITSCRIPT_PARAMS = "defaults 64"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "neard.service"
|