mirror of
https://git.yoctoproject.org/poky
synced 2026-03-19 05:39:39 +01:00
845bcf0b1b
Fixes: ERROR: QA Issue: non -staticdev package contains static .a library: lib32-libgcov-dev path '/work/x86-pokymllib32-linux/lib32-libgcc-4.7.0+svnr186651-r0/packages-split/lib32-libgcov-dev/usr/lib/i586-pokymllib32-linux/4.7.1/libgcov.a' ERROR: QA run found fatal errors. Please consider fixing them. ERROR: Function failed: do_package_qa ERROR: Logfile of failure stored in: /srv/home/pokybuild/yocto-autobuilder/yocto-slave/nightly-multilib/build/build/tmp/work/x86-pokymllib32-linux/lib32-libgcc-4.7.0+svnr186651-r0/temp/log.do_package.9691 NOTE: package lib32-libgcc-4.7.0+svnr186651-r0: task do_package: Failed ERROR: Task 1077 (virtual:multilib:lib32:/srv/home/pokybuild/yocto-autobuilder/yocto-slave/nightly-multilib/build/meta/recipes-devtools/gcc/libgcc_4.7.bb, do_package) failed with exit code '1' (From OE-Core rev: dd303065890e44f6f2c986988938c3599ea94e4f) Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
71 lines
1.9 KiB
BlitzBasic
71 lines
1.9 KiB
BlitzBasic
require recipes-devtools/gcc/gcc-${PV}.inc
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
DEPENDS = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++"
|
|
|
|
PKGSUFFIX = ""
|
|
PKGSUFFIX_virtclass-nativesdk = "-nativesdk"
|
|
|
|
PACKAGES = "\
|
|
${PN} \
|
|
${PN}-dev \
|
|
${PN}-dbg \
|
|
libgcov${PKGSUFFIX}-dev \
|
|
"
|
|
|
|
FILES_${PN} = "${base_libdir}/libgcc*.so.*"
|
|
FILES_${PN}-dev = " \
|
|
${base_libdir}/libgcc*.so \
|
|
${libdir}/${TARGET_SYS}/${BINV}/*crt* \
|
|
${libdir}/${TARGET_SYS}/${BINV}/libgcc*"
|
|
FILES_libgcov${PKGSUFFIX}-dev = " \
|
|
${libdir}/${TARGET_SYS}/${BINV}/libgcov.a \
|
|
"
|
|
FILES_${PN}-dbg += "${base_libdir}/.debug/"
|
|
|
|
do_configure () {
|
|
target=`echo ${MULTIMACH_TARGET_SYS} | sed -e s#-nativesdk##`
|
|
install -d ${D}${base_libdir} ${D}${libdir}
|
|
cp -fpPR ${STAGING_INCDIR_NATIVE}/gcc-build-internal-$target/* ${B}
|
|
mkdir -p ${B}/${BPN}
|
|
cd ${B}/${BPN}
|
|
chmod a+x ${S}/${BPN}/configure
|
|
${S}/${BPN}/configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
|
|
}
|
|
|
|
do_compile () {
|
|
target=`echo ${TARGET_SYS} | sed -e s#-nativesdk##`
|
|
cd ${B}/${BPN}
|
|
oe_runmake MULTIBUILDTOP=${B}/$target/${BPN}/
|
|
}
|
|
|
|
do_install () {
|
|
target=`echo ${TARGET_SYS} | sed -e s#-nativesdk##`
|
|
cd ${B}/${BPN}
|
|
oe_runmake 'DESTDIR=${D}' MULTIBUILDTOP=${B}/$target/${BPN}/ install
|
|
|
|
# Move libgcc_s into /lib
|
|
mkdir -p ${D}${base_libdir}
|
|
if [ -f ${D}${libdir}/nof/libgcc_s.so ]; then
|
|
mv ${D}${libdir}/nof/libgcc* ${D}${base_libdir}
|
|
else
|
|
mv ${D}${libdir}/libgcc* ${D}${base_libdir} || true
|
|
fi
|
|
|
|
# install the runtime in /usr/lib/ not in /usr/lib/gcc on target
|
|
# so that cross-gcc can find it in the sysroot
|
|
|
|
mv ${D}${libdir}/gcc/* ${D}${libdir}
|
|
rm -rf ${D}${libdir}/gcc/
|
|
}
|
|
|
|
do_package_write_ipk[depends] += "virtual/${MLPREFIX}libc:do_package"
|
|
do_package_write_deb[depends] += "virtual/${MLPREFIX}libc:do_package"
|
|
do_package_write_rpm[depends] += "virtual/${MLPREFIX}libc:do_package"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|
|
|
|
INSANE_SKIP_${PN}-dev = "staticdev"
|
|
INSANE_SKIP_${MLPREFIX}libgcov${PKGSUFFIX}-dev = "staticdev"
|