mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 00:32:14 +02:00
bb6ddc3691
This is the result of automated script conversion: scripts/contrib/convert-overrides.py <oe-core directory> converting the metadata to use ":" as the override character instead of "_". (From OE-Core rev: 42344347be29f0997cc2f7636d9603b1fe1875ae) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
1.4 KiB
BlitzBasic
51 lines
1.4 KiB
BlitzBasic
SUMMARY = "Keyboard maps"
|
|
DESCRIPTION = "Keymaps and initscript to set the keymap on bootup."
|
|
SECTION = "base"
|
|
|
|
RDEPENDS:${PN} = "kbd"
|
|
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
PR = "r31"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
# As the recipe doesn't inherit systemd.bbclass, we need to set this variable
|
|
# manually to avoid unnecessary postinst/preinst generated.
|
|
python __anonymous() {
|
|
if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
|
|
d.setVar("INHIBIT_UPDATERCD_BBCLASS", "1")
|
|
}
|
|
|
|
inherit update-rc.d
|
|
|
|
SRC_URI = "file://keymap.sh \
|
|
file://GPLv2.patch"
|
|
|
|
INITSCRIPT_NAME = "keymap.sh"
|
|
INITSCRIPT_PARAMS = "start 01 S ."
|
|
|
|
S = "${WORKDIR}"
|
|
|
|
do_install () {
|
|
# Only install the script if 'sysvinit' is in DISTRO_FEATURES
|
|
# THe ulitity this script provides could be achieved by systemd-vconsole-setup.service
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','true','false',d)}; then
|
|
install -d ${D}${sysconfdir}/init.d/
|
|
install -m 0755 ${WORKDIR}/keymap.sh ${D}${sysconfdir}/init.d/
|
|
fi
|
|
}
|
|
|
|
PACKAGE_WRITE_DEPS:append = " ${@bb.utils.contains('DISTRO_FEATURES','systemd sysvinit','systemd-systemctl-native','',d)}"
|
|
pkg_postinst:${PN} () {
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd sysvinit','true','false',d)}; then
|
|
if [ -n "$D" ]; then
|
|
OPTS="--root=$D"
|
|
fi
|
|
systemctl $OPTS mask keymap.service
|
|
fi
|
|
}
|
|
|
|
ALLOW_EMPTY:${PN} = "1"
|