mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 19:39:40 +01:00
636188943d
Introducing the 5.2 linux-yocto reference kernels. 5.0 is EOL and will be removed, leaving 4.19 (LTS) and 5.2 as the reference kernels. This has been build/boot tested on all qemu architectures for core-image-kernel-dev, and graphics tesed via core-image-sato. No blocking issues have been found. (From OE-Core rev: 14472621e4a0d3d3cf4c0bc43a8b7344c10008e3) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.9 KiB
BlitzBasic
45 lines
1.9 KiB
BlitzBasic
KBRANCH ?= "v5.2/standard/preempt-rt/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# Skip processing of this recipe if it is not explicitly specified as the
|
|
# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
|
|
# to build multiple virtual/kernel providers, e.g. as dependency of
|
|
# core-image-rt-sdk, core-image-rt.
|
|
python () {
|
|
if d.getVar("KERNEL_PACKAGE_NAME") == "kernel" and d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-yocto-rt":
|
|
raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
|
|
}
|
|
|
|
SRCREV_machine ?= "abe36b584560b3ab9c4c2ece15d5e44494f02427"
|
|
SRCREV_meta ?= "552f94eb15525c2be2e56615880f1018c3bfbb8a"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;branch=${KBRANCH};name=machine \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-5.2;destsuffix=${KMETA}"
|
|
|
|
LINUX_VERSION ?= "5.2.10"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=bbea815ee2795b2f4230826c0c6b8814"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "2"
|
|
|
|
LINUX_KERNEL_TYPE = "preempt-rt"
|
|
|
|
COMPATIBLE_MACHINE = "(qemux86|qemux86-64|qemuarm|qemuarmv5|qemuarm64|qemuppc|qemumips)"
|
|
|
|
KERNEL_DEVICETREE_qemuarmv5 = "versatile-pb.dtb"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
|
|
KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
|
KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES_append = "${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "" ,d)}"
|