mirror of
https://git.yoctoproject.org/poky
synced 2026-03-12 18:29:42 +01:00
842a5d9587
(From OE-Core rev: 85bea6d2b4d54564ae5ba671dfb5b533ce8ab7a8) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
59 lines
2.2 KiB
BlitzBasic
59 lines
2.2 KiB
BlitzBasic
SUMMARY = "General purpose cryptographic library based on the code from GnuPG"
|
|
DESCRIPTION = "A cryptography library developed as a separated module of GnuPG. \
|
|
It can also be used independently of GnuPG, but depends on its error-reporting \
|
|
library Libgpg-error."
|
|
HOMEPAGE = "http://directory.fsf.org/project/libgcrypt/"
|
|
BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
|
|
SECTION = "libs"
|
|
|
|
# helper program gcryptrnd and getrandom are under GPL, rest LGPL
|
|
LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
|
|
LICENSE:${PN} = "LGPL-2.1-or-later"
|
|
LICENSE:${PN}-dev = "GPL-2.0-or-later & LGPL-2.1-or-later"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://COPYING.LIB;md5=bbb461211a33b134d42ed5ee802b37ff \
|
|
file://LICENSES;md5=ef545b6cc717747072616519a1256d69 \
|
|
"
|
|
|
|
DEPENDS = "libgpg-error"
|
|
|
|
UPSTREAM_CHECK_URI = "https://gnupg.org/download/index.html"
|
|
SRC_URI = "${GNUPG_MIRROR}/libgcrypt/libgcrypt-${PV}.tar.bz2 \
|
|
file://0001-libgcrypt-fix-m4-file-for-oe-core.patch \
|
|
file://0002-libgcrypt-fix-building-error-with-O2-in-sysroot-path.patch \
|
|
file://0004-tests-Makefile.am-fix-undefined-reference-to-pthread.patch \
|
|
file://no-native-gpg-error.patch \
|
|
file://no-bench-slope.patch \
|
|
file://run-ptest \
|
|
"
|
|
SRC_URI[sha256sum] = "ef14ae546b0084cd84259f61a55e07a38c3b53afc0f546bffcef2f01baffe9de"
|
|
|
|
# Below whitelisted CVEs are disputed and not affecting crypto libraries for any distro.
|
|
CVE_CHECK_IGNORE += "CVE-2018-12433 CVE-2018-12438"
|
|
|
|
BINCONFIG = "${bindir}/libgcrypt-config"
|
|
|
|
inherit autotools texinfo binconfig-disabled pkgconfig ptest
|
|
|
|
EXTRA_OECONF = "--disable-asm"
|
|
EXTRA_OEMAKE:class-target = "LIBTOOLFLAGS='--tag=CC'"
|
|
|
|
PACKAGECONFIG ??= "capabilities"
|
|
PACKAGECONFIG[capabilities] = "--with-capabilities,--without-capabilities,libcap"
|
|
|
|
do_configure:prepend () {
|
|
# Else this could be used in preference to the one in aclocal-copy
|
|
rm -f ${S}/m4/gpg-error.m4
|
|
}
|
|
|
|
do_install_ptest() {
|
|
cd tests
|
|
oe_runmake testdrv-build testdrv
|
|
install testdrv $(srcdir=${S}/tests ./testdrv-build --files | sort | uniq) ${D}${PTEST_PATH}
|
|
}
|
|
|
|
FILES:${PN}-dev += "${bindir}/hmac256 ${bindir}/dumpsexp"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|