mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 21:32:13 +02:00
dc80eea725
Previously, if we switch to runlevel 1 and then switch back to runlevel 5, the network interface will be brought down and the NFS service will not be restarted correctly. The problem is that the networking and rpcbind services are brought down in runlevel 1 but not brought up in runlevel 5. This patch fixes the above problem. It's based on the assumption that in sysvinit-based system, runlevel 1 does not have networking support. This patch adjusts some init script parameters used by update-rc.d. It makes sure that networking starts before rpcbind which in turn starts before mountnfs.sh. When switching to runlevel 0, 1 and 6, the umountnfs.sh is run first before stopping rpcbind service, and the network is brought down afterwards. [YOCTO #5513] (From OE-Core rev: f12e1291b51ba6692b6809570d6a9b73c70a7fe9) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
61 lines
2.1 KiB
BlitzBasic
61 lines
2.1 KiB
BlitzBasic
SUMMARY = "Universal Addresses to RPC Program Number Mapper"
|
|
DESCRIPTION = "The rpcbind utility is a server that converts RPC \
|
|
program numbers into universal addresses."
|
|
SECTION = "console/network"
|
|
HOMEPAGE = "http://sourceforge.net/projects/rpcbind/"
|
|
BUGTRACKER = "http://sourceforge.net/tracker/?group_id=201237&atid=976751"
|
|
DEPENDS = "libtirpc quota"
|
|
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b46486e4c4a416602693a711bb5bfa39 \
|
|
file://src/rpcinfo.c;beginline=1;endline=27;md5=f8a8cd2cb25ac5aa16767364fb0e3c24"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/rpcbind/rpcbind-${PV}.tar.bz2 \
|
|
file://init.d \
|
|
file://fix_host_path.patch \
|
|
file://obsolete_automake_macros.patch \
|
|
${UCLIBCPATCHES} \
|
|
file://rpcbind.conf \
|
|
file://rpcbind.service \
|
|
"
|
|
|
|
UCLIBCPATCHES_libc-uclibc = "file://0001-uclibc-nss.patch \
|
|
file://0002-uclibc-rpcsvc-defines.patch \
|
|
"
|
|
UCLIBCPATCHES ?= ""
|
|
|
|
SRC_URI[md5sum] = "1a77ddb1aaea8099ab19c351eeb26316"
|
|
SRC_URI[sha256sum] = "c92f263e0353887f16379d7708ef1fb4c7eedcf20448bc1e4838f59497a00de3"
|
|
|
|
PR = "r4"
|
|
|
|
inherit autotools update-rc.d systemd
|
|
|
|
PACKAGECONFIG ??= "tcp-wrappers"
|
|
PACKAGECONFIG[tcp-wrappers] = "--enable-libwrap,--disable-libwrap,tcp-wrappers"
|
|
|
|
INITSCRIPT_NAME = "rpcbind"
|
|
INITSCRIPT_PARAMS = "start 12 2 3 4 5 . stop 60 0 1 6 ."
|
|
|
|
SYSTEMD_SERVICE_${PN} = "rpcbind.service"
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|
|
|
|
EXTRA_OECONF += " --enable-warmstarts "
|
|
|
|
do_install_append () {
|
|
mv ${D}${bindir} ${D}${sbindir}
|
|
|
|
install -d ${D}${sysconfdir}/init.d
|
|
sed -e 's,/etc/,${sysconfdir}/,g' \
|
|
-e 's,/sbin/,${sbindir}/,g' \
|
|
${WORKDIR}/init.d > ${D}${sysconfdir}/init.d/rpcbind
|
|
chmod 0755 ${D}${sysconfdir}/init.d/rpcbind
|
|
|
|
install -m 0755 ${WORKDIR}/rpcbind.conf ${D}${sysconfdir}
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 0644 ${WORKDIR}/rpcbind.service ${D}${systemd_unitdir}/system
|
|
sed -i -e 's,@SBINDIR@,${sbindir},g' \
|
|
-e 's,@SYSCONFDIR@,${sysconfdir},g' \
|
|
${D}${systemd_unitdir}/system/rpcbind.service
|
|
}
|