mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 08:18:43 +01:00
0cb7199a8d
Fix the numpy ptests by doing the following: - Add meson to ptest RDEPENDS in the recipe; - Add python3-unittest-automake-output as a ptest RDEPENDS; - Convert run-ptest to a shell script that sets PYTEST_DEBUG_TEMPROOT to a directory inside the same path that contains the script, create that directory, and then invoke the tests with `pytest --automake` pointed at the numpy path in site-packages (copying the tests into the normal PTEST_DIRECTORY seems to cause module import breakages in some tests). This also includes skipping two problematic tests which require a C compiler and use up a lot of space, respectively; - Set 'IMAGE_ROOTFS_EXTRA_SPACE = "3048576"' for python3-numpy in core-image-ptest.bb; - Also set 'QB_MEM:virtclass-mcextend-python3-numpy = "-m 4096"' in core-image-ptest.bb; - Move python3-numpy from the PTESTS_PROBLEMS list to the PTESTS_SLOW one. Results on qemux86-64: Testsuite summary DURATION: 87 END: /usr/lib/python3-numpy/ptest 2025-04-29T17:35 STOP: ptest-runner TOTAL: 1 FAIL: 0 Note that many of the skipped tests are due to the absence of python3-mypy (which is currently in meta-python) and of a Fortran compiler. (From OE-Core rev: 7f0b5e8faa1b246531ac425c99a629eb344b21e2) Signed-off-by: Trevor Gamblin <tgamblin@baylibre.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
77 lines
2.7 KiB
BlitzBasic
77 lines
2.7 KiB
BlitzBasic
SUMMARY = "A sophisticated Numeric Processing Package for Python"
|
|
HOMEPAGE = "https://numpy.org/"
|
|
DESCRIPTION = "NumPy is the fundamental package needed for scientific computing with Python."
|
|
SECTION = "devel/python"
|
|
LICENSE = "BSD-3-Clause & BSD-2-Clause & PSF-2.0 & Apache-2.0 & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=1de863c37a83e71b1e97b64d036ea78b"
|
|
|
|
SRCNAME = "numpy"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/${SRCNAME}-${PV}.tar.gz \
|
|
file://0001-Don-t-search-usr-and-so-on-for-libraries-by-default-.patch \
|
|
file://fix_reproducibility.patch \
|
|
file://run-ptest \
|
|
"
|
|
SRC_URI[sha256sum] = "a9c0d994680cd991b1cb772e8b297340085466a6fe964bc9d4e80f5e2f43c291"
|
|
|
|
GITHUB_BASE_URI = "https://github.com/numpy/numpy/releases"
|
|
UPSTREAM_CHECK_REGEX = "releases/tag/v?(?P<pver>\d+(\.\d+)+)$"
|
|
|
|
inherit pkgconfig ptest python_mesonpy github-releases cython
|
|
|
|
S = "${WORKDIR}/numpy-${PV}"
|
|
|
|
PACKAGECONFIG[svml] = "-Ddisable-svml=false,-Ddisable-svml=true"
|
|
|
|
# Remove references to buildpaths from numpy's __config__.py
|
|
do_install:append() {
|
|
sed -i \
|
|
-e 's|${S}=||g' \
|
|
-e 's|${B}=||g' \
|
|
-e 's|${RECIPE_SYSROOT_NATIVE}=||g' \
|
|
-e 's|${RECIPE_SYSROOT_NATIVE}||g' \
|
|
-e 's|${RECIPE_SYSROOT}=||g' \
|
|
-e 's|${RECIPE_SYSROOT}||g' ${D}${PYTHON_SITEPACKAGES_DIR}/numpy/__config__.py
|
|
|
|
nativepython3 -mcompileall -s ${D} ${D}${PYTHON_SITEPACKAGES_DIR}/numpy/__config__.py
|
|
}
|
|
|
|
FILES:${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/numpy/_core/lib/*.a \
|
|
${PYTHON_SITEPACKAGES_DIR}/numpy/random/lib/*.a \
|
|
"
|
|
|
|
# install what is needed for numpy.test()
|
|
RDEPENDS:${PN} = "\
|
|
python3-compression \
|
|
python3-ctypes \
|
|
python3-datetime \
|
|
python3-difflib \
|
|
python3-doctest \
|
|
python3-email \
|
|
python3-json \
|
|
python3-misc \
|
|
python3-mmap \
|
|
python3-multiprocessing \
|
|
python3-netclient \
|
|
python3-numbers \
|
|
python3-pickle \
|
|
python3-pkgutil \
|
|
python3-pprint \
|
|
python3-pydoc \
|
|
python3-shell \
|
|
python3-threading \
|
|
python3-unittest \
|
|
"
|
|
RDEPENDS:${PN}-ptest += "\
|
|
ldd \
|
|
meson \
|
|
python3-hypothesis \
|
|
python3-pytest \
|
|
python3-resource \
|
|
python3-sortedcontainers \
|
|
python3-typing-extensions \
|
|
python3-unittest-automake-output \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|