mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 12:32:12 +02:00
844e2ebbfc
The lld linker is a standalone project under the LLVM umbrella that just depends on libLLVM and nothing else, such as clang. To reduce the build time of clang if lld is not being used, split it out into a separate recipe. To ensure that lld is present if needed, the clang-cross recipe will depend on lld-native if ld-is-lld is enable. (From OE-Core rev: 5212b69f892af8c9b080fee2c21533a2bbdd2755) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
27 lines
914 B
BlitzBasic
27 lines
914 B
BlitzBasic
# Copyright (C) 2014 Khem Raj <raj.khem@gmail.com>
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
SUMMARY = "Cross compiler wrappers for LLVM based C/C++ compiler"
|
|
HOMEPAGE = "http://clang.llvm.org/"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
|
|
SECTION = "devel"
|
|
|
|
PN = "clang-cross-${TARGET_ARCH}"
|
|
|
|
inherit cross
|
|
|
|
DEPENDS = "clang-native virtual/cross-binutils ${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', 'lld-native', '', d)}"
|
|
|
|
do_install() {
|
|
install -d ${D}${bindir}
|
|
for tool in clang clang++ clang-tidy lld ld.lld llvm-profdata \
|
|
llvm-nm llvm-ar llvm-as llvm-ranlib llvm-strip llvm-objcopy llvm-objdump llvm-readelf \
|
|
llvm-addr2line llvm-dwp llvm-size llvm-strings llvm-cov
|
|
do
|
|
if [ -x ${STAGING_BINDIR_NATIVE}/$tool ]; then
|
|
ln -sf ../$tool ${D}${bindir}/${TARGET_PREFIX}$tool
|
|
fi
|
|
done
|
|
}
|