mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
bd1cf71974
PowerPC toolchains can use the OS "linux" or "linux-gnuspe". This patch links them together so the one cross-canadian toolchain can support both. GCC_FOR_TARGET is set for the GCC recipe as otherwise configure can pick up an incorrect value. [YOCTO #5354] (From OE-Core rev: a1d6331238982b0c5d39b0a18794f6654b00d46a) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
30 lines
1017 B
PHP
30 lines
1017 B
PHP
inherit cross-canadian
|
|
|
|
DESCRIPTION = "A GNU collection of cross-canadian binary utilities for ${TARGET_ARCH} target"
|
|
PN = "binutils-cross-canadian-${TRANSLATED_TARGET_ARCH}"
|
|
BPN = "binutils"
|
|
|
|
DEPENDS = "flex-native bison-native virtual/${HOST_PREFIX}gcc-crosssdk virtual/nativesdk-libc nativesdk-zlib nativesdk-gettext"
|
|
EXTRA_OECONF += "--with-sysroot=${SDKPATH}/sysroots/${TUNE_PKGARCH}${TARGET_VENDOR}-${TARGET_OS} \
|
|
"
|
|
|
|
# We have to point binutils at a sysroot but we don't need to rebuild if this changes
|
|
# e.g. we switch between different machines with different tunes.
|
|
EXTRA_OECONF[vardepsexclude] = "TUNE_PKGARCH"
|
|
|
|
do_install () {
|
|
autotools_do_install
|
|
|
|
# We're not interested in the libs or headers, these would come from the
|
|
# nativesdk or target version of the binutils recipe
|
|
rm -rf ${D}${prefix}/${TARGET_SYS}
|
|
rm -f ${D}${libdir}/libbfd*
|
|
rm -f ${D}${libdir}/libiberty*
|
|
rm -f ${D}${libdir}/libopcodes*
|
|
rm -f ${D}${includedir}/*.h
|
|
|
|
cross_canadian_bindirlinks
|
|
}
|
|
|
|
BBCLASSEXTEND = ""
|