mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 03:32:12 +02:00
07be05c698
This update was made with the convert-scruri.py script in scripts/contrib
This script handles two emerging issues:
1. There is uncertainty about the default branch name in git going forward.
To try and cover the different possible outcomes, add branch names to all
git:// and gitsm:// SRC_URI entries.
2. Github are dropping support for git:// protocol fetching, so remap github
urls as needed. For more details see:
https://github.blog/2021-09-01-improving-git-protocol-security-github/
(From OE-Core rev: 827a805349f9732b2a5fa9184dc7922af36de327)
Signed-off-by: Steve Sakoman <steve@sakoman.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
2.0 KiB
BlitzBasic
50 lines
2.0 KiB
BlitzBasic
SUMMARY = "RISC-V Open Source Supervisor Binary Interface (OpenSBI)"
|
|
DESCRIPTION = "OpenSBI aims to provide an open-source and extensible implementation of the RISC-V SBI specification for a platform specific firmware (M-mode) and a general purpose OS, hypervisor or bootloader (S-mode or HS-mode). OpenSBI implementation can be easily extended by RISC-V platform or System-on-Chip vendors to fit a particular hadware configuration."
|
|
HOMEPAGE = "https://github.com/riscv/opensbi"
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING.BSD;md5=42dd9555eb177f35150cf9aa240b61e5"
|
|
|
|
require opensbi-payloads.inc
|
|
|
|
inherit autotools-brokensep deploy
|
|
|
|
SRCREV = "ac5e821d50be631f26274765a59bc1b444ffd862"
|
|
SRC_URI = "git://github.com/riscv/opensbi.git;branch=master;protocol=https \
|
|
file://0001-Makefile-Don-t-specify-mabi-or-march.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_OEMAKE += "PLATFORM=${RISCV_SBI_PLAT} I=${D}"
|
|
# If RISCV_SBI_PAYLOAD is set then include it as a payload
|
|
EXTRA_OEMAKE_append = " ${@riscv_get_extra_oemake_image(d)}"
|
|
|
|
# Required if specifying a custom payload
|
|
do_compile[depends] += "${@riscv_get_do_compile_depends(d)}"
|
|
|
|
do_install_append() {
|
|
# In the future these might be required as a dependency for other packages.
|
|
# At the moment just delete them to avoid warnings
|
|
rm -r ${D}/include
|
|
rm -r ${D}/platform/${RISCV_SBI_PLAT}/lib
|
|
rm -r ${D}/platform/${RISCV_SBI_PLAT}/firmware/payloads
|
|
rm -r ${D}/lib
|
|
}
|
|
|
|
do_deploy () {
|
|
install -m 755 ${D}/platform/${RISCV_SBI_PLAT}/firmware/fw_payload.* ${DEPLOYDIR}/
|
|
install -m 755 ${D}/platform/${RISCV_SBI_PLAT}/firmware/fw_jump.* ${DEPLOYDIR}/
|
|
install -m 755 ${D}/platform/${RISCV_SBI_PLAT}/firmware/fw_dynamic.* ${DEPLOYDIR}/
|
|
}
|
|
|
|
addtask deploy before do_build after do_install
|
|
|
|
FILES_${PN} += "/platform/${RISCV_SBI_PLAT}/firmware/fw_jump.*"
|
|
FILES_${PN} += "/platform/${RISCV_SBI_PLAT}/firmware/fw_payload.*"
|
|
FILES_${PN} += "/platform/${RISCV_SBI_PLAT}/firmware/fw_dynamic.*"
|
|
|
|
COMPATIBLE_HOST = "(riscv64|riscv32).*"
|
|
INHIBIT_PACKAGE_STRIP = "1"
|
|
|
|
SECURITY_CFLAGS = ""
|