mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 03:32:13 +02:00
fca7b22674
(From OE-Core rev: 88c0290520c9e4982d25c20e783bd91eec016b52) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit d4c37ca1f1e97d53045521e9894dc9ed5b1c22a1) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.6 KiB
BlitzBasic
48 lines
1.6 KiB
BlitzBasic
SUMMARY = "Userspace library to access USB (version 1.0)"
|
|
DESCRIPTION = "A cross-platform library to access USB devices from Linux, \
|
|
macOS, Windows, OpenBSD/NetBSD, Haiku and Solaris userspace."
|
|
HOMEPAGE = "https://libusb.info"
|
|
BUGTRACKER = "http://www.libusb.org/report"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
SRC_URI = "https://github.com/libusb/libusb/releases/download/v${PV}/libusb-${PV}.tar.bz2 \
|
|
file://no-dll.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "466267889daead47674df933cea9cacb"
|
|
SRC_URI[sha256sum] = "75aeb9d59a4fdb800d329a545c2e6799f732362193b465ea198f2aa275518157"
|
|
|
|
S = "${WORKDIR}/libusb-${PV}"
|
|
|
|
inherit autotools pkgconfig ptest
|
|
|
|
PACKAGECONFIG_class-target ??= "udev"
|
|
PACKAGECONFIG[udev] = "--enable-udev,--disable-udev,udev"
|
|
|
|
EXTRA_OECONF = "--libdir=${base_libdir}"
|
|
|
|
do_install_append() {
|
|
install -d ${D}${libdir}
|
|
if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then
|
|
mv ${D}${base_libdir}/pkgconfig ${D}${libdir}
|
|
fi
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C tests stress
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -m 755 ${B}/tests/.libs/stress ${D}${PTEST_PATH}
|
|
}
|
|
|
|
FILES_${PN} += "${base_libdir}/*.so.*"
|
|
|
|
FILES_${PN}-dev += "${base_libdir}/*.so ${base_libdir}/*.la"
|