mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
9107d6ca14
This patch is comparatively large and invasive. It does only do one thing, switching the system to build using recipe specific sysroots and where changes could be isolated from it, that has been done. With the current single sysroot approach, its possible for software to find things which aren't in their dependencies. This leads to a determinism problem and is a growing issue in several of the market segments where OE makes sense. The way to solve this problem for OE is to have seperate sysroots for each recipe and these will only contain the dependencies for that recipe. Its worth noting that this is not task specific sysroots and that OE's dependencies do vary enormously by task. This did result in some implementation challenges. There is nothing stopping the implementation of task specific sysroots at some later point based on this work but that as deemed a bridge too far right now. Implementation details: * Rather than installing the sysroot artefacts into a combined sysroots, they are now placed in TMPDIR/sysroot-components/PACKAGE_ARCH/PN. * WORKDIR/recipe-sysroot and WORKDIR/recipe-sysroot-native are built by hardlinking in files from the sysroot-component trees. These new directories are known as RECIPE_SYSROOT and RECIPE_SYSROOT_NATIVE. * This construction is primarily done by a new do_prepare_recipe_sysroot task which runs before do_configure and consists of a call to the extend_recipe_sysroot function. * Other tasks need things in the sysroot before/after this, e.g. do_patch needs quilt-native and do_package_write_deb needs dpkg-native. The code therefore inspects the dependencies for each task and adds extend_recipe_sysroot as a prefunc if it has populate_sysroot dependencies. * We have to do a search/replace 'fixme' operation on the files installed into the sysroot to change hardcoded paths into the correct ones. We create a fixmepath file in the component directory which lists the files which need this operation. * Some files have "postinstall" commands which need to run against them, e.g. gdk-pixbuf each time a new loader is added. These are handled by adding files in bindir with the name prefixed by "postinst-" and are run in each sysroot as its created if they're present. This did mean most sstate postinstalls have to be rewritten but there shouldn't be many of them. * Since a recipe can have multiple tasks and these tasks can run against each other at the same time we have to have a lock when we perform write operations against the sysroot. We also have to maintain manifests of what we install against a task checksum of the dependency. If the checksum changes, we remove its files and then add the new ones. * The autotools logic for filtering the view of m4 files is no longer needed (and was the model for the way extend_recipe_sysroot works). * For autotools, we used to build a combined m4 macros directory which had both the native and target m4 files. We can no longer do this so we use the target sysroot as the default and add the native sysroot as an extra backup include path. If we don't do this, we'd have to build target pkg-config before we could built anything using pkg-config for example (ditto gettext). Such dependencies would be painful so we haven't required that. * PKDDATA_DIR was moved out the sysroot and works as before using sstate to build a hybrid copy for each machine. The paths therefore changed, the behaviour did not. * The ccache class had to be reworked to function with rss. * The TCBOOTSTRAP sysroot for compiler bootstrap is no longer needed but the -initial data does have to be filtered out from the main recipe sysroots. Putting "-initial" in a normal recipe name therefore remains a bad idea. * The logic in insane needed tweaks to deal with the new path layout, as did the debug source file extraction code in package.bbclass. * The logic in sstate.bbclass had to be rewritten since it previously only performed search and replace on extracted sstate and we now need this to happen even if the compiled path was "correct". This in theory could cause a mild performance issue but since the sysroot data was the main data that needed this and we'd have to do it there regardless with rss, I've opted just to change the way the class for everything. The built output used to build the sstate output is now retained and installed rather than deleted. * The search and replace logic used in sstate objects also seemed weak/incorrect and didn't hold up against testing. This has been rewritten too. There are some assumptions made about paths, we save the 'proper' search and replace operations to fixmepath.cmd but then ignore this. What is here works but is a little hardcoded and an area for future improvement. * In order to work with eSDK we need a way to build something that looks like the old style sysroot. "bitbake build-sysroots" will construct such a sysroot based on everything in the components directory that matches the current MACHINE. It will allow transition of external tools and can built target or native variants or both. It also supports a clean task. I'd suggest not relying on this for anything other than transitional purposes though. To see XXX in that sysroot, you'd have to have built that in a previous bitbake invocation. * pseudo is run out of its components directory. This is fine as its statically linked. * The hacks for wayland to see allarch dependencies in the multilib case are no longer needed and can be dropped. * wic needed more extensive changes to work with rss and the fixes are in a separate commit series * Various oe-selftest tweaks were needed since tests did assume the location to binaries and the combined sysroot in several cases. * Most missing dependencies this work found have been sent out as separate patches as they were found but a few tweaks are still included here. * A late addition is that extend_recipe_sysroot became multilib aware and able to populate multilib sysroots. I had hoped not to have to add that complexity but the meta-environment recipe forced my hand. That implementation can probably be neater but this is on the list of things to cleanup later at this point. In summary, the impact people will likely see after this change: * Recipes may fail with missing dependencies, particularly native tools like gettext-native, glib-2.0-native and libxml2.0-native. Some hosts have these installed and will mask these errors * Any recipe/class using SSTATEPOSTINSTFUNCS will need that code rewriting into a postinst * There was a separate patch series dealing with roots postinst native dependency issues. Any postinst which expects native tools at rootfs time will need to mark that dependency with PACKAGE_WRITE_DEPS. There could well be other issues. This has been tested repeatedly against our autobuilders and oe-selftest and issues found have been fixed. We believe at least OE-Core is in good shape but that doesn't mean we've found all the issues. Also, the logging is a bit chatty at the moment. It does help if something goes wrong and goes to the task logfiles, not the console so I've intentionally left this like that for now. We can turn it down easily enough in due course. (From OE-Core rev: 809746f56df4b91af014bf6a3f28997d6698ac78) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
254 lines
10 KiB
Plaintext
254 lines
10 KiB
Plaintext
inherit useradd_base
|
|
|
|
# base-passwd-cross provides the default passwd and group files in the
|
|
# target sysroot, and shadow -native and -sysroot provide the utilities
|
|
# and support files needed to add and modify user and group accounts
|
|
DEPENDS_append_class-target = " base-files shadow-native shadow-sysroot shadow base-passwd"
|
|
PACKAGE_WRITE_DEPS += "shadow-native"
|
|
|
|
# This preinstall function can be run in four different contexts:
|
|
#
|
|
# a) Before do_install
|
|
# b) At do_populate_sysroot_setscene when installing from sstate packages
|
|
# c) As the preinst script in the target package at do_rootfs time
|
|
# d) As the preinst script in the target package on device as a package upgrade
|
|
#
|
|
useradd_preinst () {
|
|
OPT=""
|
|
SYSROOT=""
|
|
|
|
if test "x$D" != "x"; then
|
|
# Installing into a sysroot
|
|
SYSROOT="$D"
|
|
OPT="--root $D"
|
|
|
|
# Make sure login.defs is there, this is to make debian package backend work
|
|
# correctly while doing rootfs.
|
|
# The problem here is that if /etc/login.defs is treated as a config file for
|
|
# shadow package, then while performing preinsts for packages that depend on
|
|
# shadow, there might only be /etc/login.def.dpkg-new there in root filesystem.
|
|
if [ ! -e $D${sysconfdir}/login.defs -a -e $D${sysconfdir}/login.defs.dpkg-new ]; then
|
|
cp $D${sysconfdir}/login.defs.dpkg-new $D${sysconfdir}/login.defs
|
|
fi
|
|
|
|
# user/group lookups should match useradd/groupadd --root
|
|
export PSEUDO_PASSWD="$SYSROOT:${STAGING_DIR_NATIVE}"
|
|
fi
|
|
|
|
# If we're not doing a special SSTATE/SYSROOT install
|
|
# then set the values, otherwise use the environment
|
|
if test "x$UA_SYSROOT" = "x"; then
|
|
# Installing onto a target
|
|
# Add groups and users defined only for this package
|
|
GROUPADD_PARAM="${GROUPADD_PARAM}"
|
|
USERADD_PARAM="${USERADD_PARAM}"
|
|
GROUPMEMS_PARAM="${GROUPMEMS_PARAM}"
|
|
fi
|
|
|
|
# Perform group additions first, since user additions may depend
|
|
# on these groups existing
|
|
if test "x`echo $GROUPADD_PARAM | tr -d '[:space:]'`" != "x"; then
|
|
echo "Running groupadd commands..."
|
|
# Invoke multiple instances of groupadd for parameter lists
|
|
# separated by ';'
|
|
opts=`echo "$GROUPADD_PARAM" | cut -d ';' -f 1 | sed -e 's#[ \t]*$##'`
|
|
remaining=`echo "$GROUPADD_PARAM" | cut -d ';' -f 2- | sed -e 's#[ \t]*$##'`
|
|
while test "x$opts" != "x"; do
|
|
perform_groupadd "$SYSROOT" "$OPT $opts"
|
|
if test "x$opts" = "x$remaining"; then
|
|
break
|
|
fi
|
|
opts=`echo "$remaining" | cut -d ';' -f 1 | sed -e 's#[ \t]*$##'`
|
|
remaining=`echo "$remaining" | cut -d ';' -f 2- | sed -e 's#[ \t]*$##'`
|
|
done
|
|
fi
|
|
|
|
if test "x`echo $USERADD_PARAM | tr -d '[:space:]'`" != "x"; then
|
|
echo "Running useradd commands..."
|
|
# Invoke multiple instances of useradd for parameter lists
|
|
# separated by ';'
|
|
opts=`echo "$USERADD_PARAM" | cut -d ';' -f 1 | sed -e 's#[ \t]*$##'`
|
|
remaining=`echo "$USERADD_PARAM" | cut -d ';' -f 2- | sed -e 's#[ \t]*$##'`
|
|
while test "x$opts" != "x"; do
|
|
perform_useradd "$SYSROOT" "$OPT $opts"
|
|
if test "x$opts" = "x$remaining"; then
|
|
break
|
|
fi
|
|
opts=`echo "$remaining" | cut -d ';' -f 1 | sed -e 's#[ \t]*$##'`
|
|
remaining=`echo "$remaining" | cut -d ';' -f 2- | sed -e 's#[ \t]*$##'`
|
|
done
|
|
fi
|
|
|
|
if test "x`echo $GROUPMEMS_PARAM | tr -d '[:space:]'`" != "x"; then
|
|
echo "Running groupmems commands..."
|
|
# Invoke multiple instances of groupmems for parameter lists
|
|
# separated by ';'
|
|
opts=`echo "$GROUPMEMS_PARAM" | cut -d ';' -f 1 | sed -e 's#[ \t]*$##'`
|
|
remaining=`echo "$GROUPMEMS_PARAM" | cut -d ';' -f 2- | sed -e 's#[ \t]*$##'`
|
|
while test "x$opts" != "x"; do
|
|
perform_groupmems "$SYSROOT" "$OPT $opts"
|
|
if test "x$opts" = "x$remaining"; then
|
|
break
|
|
fi
|
|
opts=`echo "$remaining" | cut -d ';' -f 1 | sed -e 's#[ \t]*$##'`
|
|
remaining=`echo "$remaining" | cut -d ';' -f 2- | sed -e 's#[ \t]*$##'`
|
|
done
|
|
fi
|
|
}
|
|
|
|
useradd_sysroot () {
|
|
# Pseudo may (do_prepare_recipe_sysroot) or may not (do_populate_sysroot_setscene) be running
|
|
# at this point so we're explicit about the environment so pseudo can load if
|
|
# not already present.
|
|
export PSEUDO="${FAKEROOTENV} PSEUDO_LOCALSTATEDIR=${STAGING_DIR_TARGET}${localstatedir}/pseudo ${PSEUDO_SYSROOT}${bindir_native}/pseudo"
|
|
|
|
# Explicitly set $D since it isn't set to anything
|
|
# before do_prepare_recipe_sysroot
|
|
D=${STAGING_DIR_TARGET}
|
|
|
|
# Add groups and users defined for all recipe packages
|
|
GROUPADD_PARAM="${@get_all_cmd_params(d, 'groupadd')}"
|
|
USERADD_PARAM="${@get_all_cmd_params(d, 'useradd')}"
|
|
GROUPMEMS_PARAM="${@get_all_cmd_params(d, 'groupmems')}"
|
|
|
|
# Tell the system to use the environment vars
|
|
UA_SYSROOT=1
|
|
|
|
useradd_preinst
|
|
}
|
|
|
|
python useradd_sysroot_sstate () {
|
|
task = d.getVar("BB_CURRENTTASK")
|
|
if task == "package_setscene":
|
|
bb.build.exec_func("useradd_sysroot", d)
|
|
elif task == "prepare_recipe_sysroot":
|
|
scriptfile = d.expand("${RECIPE_SYSROOT}${bindir}/postinst-useradd-${PN}")
|
|
bb.utils.mkdirhier(os.path.dirname(scriptfile))
|
|
with open(scriptfile, 'w') as script:
|
|
script.write("#!/bin/sh\n")
|
|
bb.data.emit_func("useradd_sysroot", script, d)
|
|
script.write("useradd_sysroot\n")
|
|
os.chmod(scriptfile, 0o755)
|
|
bb.build.exec_func("useradd_sysroot", d)
|
|
}
|
|
|
|
userdel_sysroot_sstate () {
|
|
if test "x${STAGING_DIR_TARGET}" != "x"; then
|
|
if [ "${BB_CURRENTTASK}" = "clean" ]; then
|
|
export PSEUDO="${FAKEROOTENV} PSEUDO_LOCALSTATEDIR=${STAGING_DIR_TARGET}${localstatedir}/pseudo ${PSEUDO_SYSROOT}${bindir_native}/pseudo"
|
|
OPT="--root ${STAGING_DIR_TARGET}"
|
|
|
|
# Remove groups and users defined for package
|
|
GROUPADD_PARAM="${@get_all_cmd_params(d, 'groupadd')}"
|
|
USERADD_PARAM="${@get_all_cmd_params(d, 'useradd')}"
|
|
|
|
user=`echo "$USERADD_PARAM" | cut -d ';' -f 1 | awk '{ print $NF }'`
|
|
remaining=`echo "$USERADD_PARAM" | cut -d ';' -f 2- -s | sed -e 's#[ \t]*$##'`
|
|
while test "x$user" != "x"; do
|
|
perform_userdel "${STAGING_DIR_TARGET}" "$OPT $user"
|
|
user=`echo "$remaining" | cut -d ';' -f 1 | awk '{ print $NF }'`
|
|
remaining=`echo "$remaining" | cut -d ';' -f 2- -s | sed -e 's#[ \t]*$##'`
|
|
done
|
|
|
|
user=`echo "$GROUPADD_PARAM" | cut -d ';' -f 1 | awk '{ print $NF }'`
|
|
remaining=`echo "$GROUPADD_PARAM" | cut -d ';' -f 2- -s | sed -e 's#[ \t]*$##'`
|
|
while test "x$user" != "x"; do
|
|
perform_groupdel "${STAGING_DIR_TARGET}" "$OPT $user"
|
|
user=`echo "$remaining" | cut -d ';' -f 1 | awk '{ print $NF }'`
|
|
remaining=`echo "$remaining" | cut -d ';' -f 2- -s | sed -e 's#[ \t]*$##'`
|
|
done
|
|
|
|
fi
|
|
fi
|
|
}
|
|
|
|
#SSTATECLEANFUNCS_append_class-target = " userdel_sysroot_sstate"
|
|
|
|
do_prepare_recipe_sysroot[postfuncs] += "${SYSROOTFUNC}"
|
|
SYSROOTFUNC_class-target = "useradd_sysroot_sstate"
|
|
SYSROOTFUNC = ""
|
|
|
|
SSTATEPREINSTFUNCS_append_class-target = " useradd_sysroot_sstate"
|
|
|
|
do_package_setscene[depends] += "${USERADDSETSCENEDEPS}"
|
|
do_populate_sysroot_setscene[depends] += "${USERADDSETSCENEDEPS}"
|
|
USERADDSETSCENEDEPS_class-target = "${MLPREFIX}base-passwd:do_populate_sysroot_setscene pseudo-native:do_populate_sysroot_setscene shadow-native:do_populate_sysroot_setscene ${MLPREFIX}shadow-sysroot:do_populate_sysroot_setscene"
|
|
USERADDSETSCENEDEPS = ""
|
|
|
|
# Recipe parse-time sanity checks
|
|
def update_useradd_after_parse(d):
|
|
useradd_packages = d.getVar('USERADD_PACKAGES')
|
|
|
|
if not useradd_packages:
|
|
bb.fatal("%s inherits useradd but doesn't set USERADD_PACKAGES" % d.getVar('FILE', False))
|
|
|
|
for pkg in useradd_packages.split():
|
|
if not d.getVar('USERADD_PARAM_%s' % pkg) and not d.getVar('GROUPADD_PARAM_%s' % pkg) and not d.getVar('GROUPMEMS_PARAM_%s' % pkg):
|
|
bb.fatal("%s inherits useradd but doesn't set USERADD_PARAM, GROUPADD_PARAM or GROUPMEMS_PARAM for package %s" % (d.getVar('FILE', False), pkg))
|
|
|
|
python __anonymous() {
|
|
if not bb.data.inherits_class('nativesdk', d) \
|
|
and not bb.data.inherits_class('native', d):
|
|
update_useradd_after_parse(d)
|
|
}
|
|
|
|
# Return a single [GROUP|USER]ADD_PARAM formatted string which includes the
|
|
# [group|user]add parameters for all USERADD_PACKAGES in this recipe
|
|
def get_all_cmd_params(d, cmd_type):
|
|
import string
|
|
|
|
param_type = cmd_type.upper() + "_PARAM_%s"
|
|
params = []
|
|
|
|
useradd_packages = d.getVar('USERADD_PACKAGES') or ""
|
|
for pkg in useradd_packages.split():
|
|
param = d.getVar(param_type % pkg)
|
|
if param:
|
|
params.append(param.rstrip(" ;"))
|
|
|
|
return "; ".join(params)
|
|
|
|
# Adds the preinst script into generated packages
|
|
fakeroot python populate_packages_prepend () {
|
|
def update_useradd_package(pkg):
|
|
bb.debug(1, 'adding user/group calls to preinst for %s' % pkg)
|
|
|
|
"""
|
|
useradd preinst is appended here because pkg_preinst may be
|
|
required to execute on the target. Not doing so may cause
|
|
useradd preinst to be invoked twice, causing unwanted warnings.
|
|
"""
|
|
preinst = d.getVar('pkg_preinst_%s' % pkg) or d.getVar('pkg_preinst')
|
|
if not preinst:
|
|
preinst = '#!/bin/sh\n'
|
|
preinst += 'bbnote () {\n\techo "NOTE: $*"\n}\n'
|
|
preinst += 'bbwarn () {\n\techo "WARNING: $*"\n}\n'
|
|
preinst += 'bbfatal () {\n\techo "ERROR: $*"\n\texit 1\n}\n'
|
|
preinst += 'perform_groupadd () {\n%s}\n' % d.getVar('perform_groupadd')
|
|
preinst += 'perform_useradd () {\n%s}\n' % d.getVar('perform_useradd')
|
|
preinst += 'perform_groupmems () {\n%s}\n' % d.getVar('perform_groupmems')
|
|
preinst += d.getVar('useradd_preinst')
|
|
d.setVar('pkg_preinst_%s' % pkg, preinst)
|
|
|
|
# RDEPENDS setup
|
|
rdepends = d.getVar("RDEPENDS_%s" % pkg) or ""
|
|
rdepends += ' ' + d.getVar('MLPREFIX', False) + 'base-passwd'
|
|
rdepends += ' ' + d.getVar('MLPREFIX', False) + 'shadow'
|
|
# base-files is where the default /etc/skel is packaged
|
|
rdepends += ' ' + d.getVar('MLPREFIX', False) + 'base-files'
|
|
d.setVar("RDEPENDS_%s" % pkg, rdepends)
|
|
|
|
# Add the user/group preinstall scripts and RDEPENDS requirements
|
|
# to packages specified by USERADD_PACKAGES
|
|
if not bb.data.inherits_class('nativesdk', d) \
|
|
and not bb.data.inherits_class('native', d):
|
|
useradd_packages = d.getVar('USERADD_PACKAGES') or ""
|
|
for pkg in useradd_packages.split():
|
|
update_useradd_package(pkg)
|
|
}
|
|
|
|
# Use the following to extend the useradd with custom functions
|
|
USERADDEXTENSION ?= ""
|
|
|
|
inherit ${USERADDEXTENSION}
|