mirror of
https://git.yoctoproject.org/poky
synced 2026-02-06 08:48:45 +01:00
91e14d3a8e
singlevar in lparser.c in Lua through 5.4.4 lacks a certain luaK_exp2anyregup call, leading to a heap-based buffer over-read that might affect a system that compiles untrusted Lua code. https://nvd.nist.gov/vuln/detail/CVE-2022-28805 (From OE-Core rev: d2ba3b8850d461bc7b773240cdf15b22b31a3f9e) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
59 lines
2.1 KiB
BlitzBasic
59 lines
2.1 KiB
BlitzBasic
DESCRIPTION = "Lua is a powerful light-weight programming language designed \
|
|
for extending applications."
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://doc/readme.html;beginline=307;endline=330;md5=79c3f6b19ad05efe24c1681f025026bb"
|
|
HOMEPAGE = "http://www.lua.org/"
|
|
|
|
SRC_URI = "http://www.lua.org/ftp/lua-${PV}.tar.gz;name=tarballsrc \
|
|
file://lua.pc.in \
|
|
file://CVE-2022-28805.patch \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'ptest', 'http://www.lua.org/tests/lua-${PV_testsuites}-tests.tar.gz;name=tarballtest file://run-ptest ', '', d)} \
|
|
"
|
|
|
|
# if no test suite matches PV release of Lua exactly, download the suite for the closest Lua release.
|
|
PV_testsuites = "5.4.4"
|
|
|
|
SRC_URI[tarballsrc.sha256sum] = "164c7849653b80ae67bec4b7473b884bf5cc8d2dca05653475ec2ed27b9ebf61"
|
|
SRC_URI[tarballtest.sha256sum] = "04d28355cd67a2299dfe5708b55a0ff221ccb1a3907a3113cc103ccc05ac6aad"
|
|
|
|
inherit pkgconfig binconfig ptest
|
|
|
|
PACKAGECONFIG ??= "readline"
|
|
PACKAGECONFIG[readline] = ",,readline"
|
|
|
|
TARGET_CC_ARCH += " -fPIC ${LDFLAGS}"
|
|
EXTRA_OEMAKE = "'CC=${CC} -fPIC' 'MYCFLAGS=${CFLAGS} -fPIC' MYLDFLAGS='${LDFLAGS}' 'AR=ar rcD' 'RANLIB=ranlib -D'"
|
|
|
|
do_configure:prepend() {
|
|
sed -i -e s:/usr/local:${prefix}:g src/luaconf.h
|
|
sed -i -e s:lib/lua/:${baselib}/lua/:g src/luaconf.h
|
|
}
|
|
|
|
do_compile () {
|
|
oe_runmake ${@bb.utils.contains('PACKAGECONFIG', 'readline', 'linux-readline', 'linux', d)}
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake \
|
|
'INSTALL_TOP=${D}${prefix}' \
|
|
'INSTALL_BIN=${D}${bindir}' \
|
|
'INSTALL_INC=${D}${includedir}/' \
|
|
'INSTALL_MAN=${D}${mandir}/man1' \
|
|
'INSTALL_SHARE=${D}${datadir}/lua' \
|
|
'INSTALL_LIB=${D}${libdir}' \
|
|
'INSTALL_CMOD=${D}${libdir}/lua/5.4' \
|
|
install
|
|
install -d ${D}${libdir}/pkgconfig
|
|
|
|
sed -e s/@VERSION@/${PV}/ ${WORKDIR}/lua.pc.in > ${WORKDIR}/lua.pc
|
|
install -m 0644 ${WORKDIR}/lua.pc ${D}${libdir}/pkgconfig/
|
|
rmdir ${D}${datadir}/lua/5.4
|
|
rmdir ${D}${datadir}/lua
|
|
}
|
|
|
|
do_install_ptest () {
|
|
cp -R --no-dereference --preserve=mode,links -v ${WORKDIR}/lua-${PV_testsuites}-tests ${D}${PTEST_PATH}/test
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|