mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 21:32:13 +02:00
29a7e791aa
Install acl test suite and run it as ptest. nfs test cases need depend on nfs service. So exclude them order to make ptest all pass. (From OE-Core rev: 9b42aacca362ea5c404e2fd3ac25a51790ba41a5) Signed-off-by: Chong Lu <Chong.Lu@windriver.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.2 KiB
PHP
39 lines
1.2 KiB
PHP
SUMMARY = "Utilities for managing POSIX Access Control Lists"
|
|
HOMEPAGE = "http://savannah.nongnu.org/projects/acl/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "LGPLv2.1+ & GPLv2+"
|
|
LICENSE_${PN} = "GPLv2+"
|
|
LICENSE_lib${BPN} = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://doc/COPYING;md5=c781d70ed2b4d48995b790403217a249 \
|
|
file://doc/COPYING.LGPL;md5=9e9a206917f8af112da634ce3ab41764"
|
|
|
|
DEPENDS = "attr"
|
|
SRC_URI = "http://download.savannah.gnu.org/releases/acl/${BP}.src.tar.gz \
|
|
file://run-ptest \
|
|
"
|
|
|
|
require ea-acl.inc
|
|
|
|
# avoid RPATH hardcode to staging dir
|
|
do_configure_append() {
|
|
sed -i ${S}/config.status -e s,^\\\(hardcode_into_libs=\\\).*$,\\1\'no\',
|
|
${S}/config.status
|
|
}
|
|
|
|
# libdir should point to .la
|
|
do_install_append() {
|
|
sed -i ${D}${libdir}/libacl.la -e \
|
|
s,^libdir=\'${base_libdir}\'$,libdir=\'${libdir}\',
|
|
}
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
tar -cf - test/ --exclude nfs | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
mkdir ${D}${PTEST_PATH}/include
|
|
cp ${S}/include/builddefs ${S}/include/buildmacros ${S}/include/buildrules ${D}${PTEST_PATH}/include/
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest = "bash coreutils perl perl-module-filehandle perl-module-getopt-std perl-module-posix shadow"
|