mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 00:32:14 +02:00
37b13b7d53
(From OE-Core rev: 78450d4a591bcb3573fb8ff7149a8c5aa5e1617d) Signed-off-by: Wang Mingyu <wangmy@cn.fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.8 KiB
BlitzBasic
45 lines
1.8 KiB
BlitzBasic
SUMMARY = "Interface for user-level network packet capture"
|
|
DESCRIPTION = "Libpcap provides a portable framework for low-level network \
|
|
monitoring. Libpcap can provide network statistics collection, \
|
|
security monitoring and network debugging."
|
|
HOMEPAGE = "http://www.tcpdump.org/"
|
|
BUGTRACKER = "http://sourceforge.net/tracker/?group_id=53067&atid=469577"
|
|
SECTION = "libs/network"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5eb289217c160e2920d2e35bddc36453 \
|
|
file://pcap.h;beginline=1;endline=32;md5=39af3510e011f34b8872f120b1dc31d2"
|
|
DEPENDS = "flex-native bison-native"
|
|
|
|
SRC_URI = "https://www.tcpdump.org/release/${BP}.tar.gz \
|
|
"
|
|
SRC_URI[md5sum] = "8c12dc19dd7e0d02d2bb6596eb5a71c7"
|
|
SRC_URI[sha256sum] = "8d12b42623eeefee872f123bd0dc85d535b00df4d42e865f993c40f7bfc92b1e"
|
|
|
|
inherit autotools binconfig-disabled pkgconfig
|
|
|
|
BINCONFIG = "${bindir}/pcap-config"
|
|
|
|
# Explicitly disable dag support. We don't have recipe for it and if enabled here,
|
|
# configure script poisons the include dirs with /usr/local/include even when the
|
|
# support hasn't been detected.
|
|
EXTRA_OECONF = " \
|
|
--with-pcap=linux \
|
|
--without-dag \
|
|
"
|
|
EXTRA_AUTORECONF += "--exclude=aclocal"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez5', '', d)} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} \
|
|
"
|
|
PACKAGECONFIG[bluez5] = "--enable-bluetooth,--disable-bluetooth,bluez5"
|
|
PACKAGECONFIG[dbus] = "--enable-dbus,--disable-dbus,dbus"
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
|
|
PACKAGECONFIG[libnl] = "--with-libnl,--without-libnl,libnl"
|
|
|
|
do_configure_prepend () {
|
|
#remove hardcoded references to /usr/include
|
|
sed 's|\([ "^'\''I]\+\)/usr/include/|\1${STAGING_INCDIR}/|g' -i ${S}/configure.ac
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|