mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 18:32:15 +02:00
900aae50c9
Add the following patches from stable-2.12 branch of lttng repository to fix errors when building lttng-modules against 5.12+ kernel since they are not present on the release 2.12.5: - 17cd2dc9 fix: block: add a disk_uevent helper (v5.12) - 127135b6 fix backport: block: add a disk_uevent helper (v5.12) - 853d5903 fix: mm, tracing: kfree event name mismatching with provider kmem (v5.12) (From OE-Core rev: 86bcab9e9f4ee5e06f7db8c75d4b983fd2be59d2) Signed-off-by: Vinicius Aquino <vinicius.aquino@ossystems.com.br> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 2538ba2b3490e3599d9ccd637aa8486ea428f1b0) Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
2.2 KiB
BlitzBasic
50 lines
2.2 KiB
BlitzBasic
SECTION = "devel"
|
|
SUMMARY = "Linux Trace Toolkit KERNEL MODULE"
|
|
DESCRIPTION = "The lttng-modules 2.0 package contains the kernel tracer modules"
|
|
HOMEPAGE = "https://lttng.org/"
|
|
LICENSE = "LGPLv2.1 & GPLv2 & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=3f882d431dc0f32f1f44c0707aa41128"
|
|
|
|
inherit module
|
|
|
|
include lttng-platforms.inc
|
|
|
|
SRC_URI = "https://lttng.org/files/${BPN}/${BPN}-${PV}.tar.bz2 \
|
|
file://Makefile-Do-not-fail-if-CONFIG_TRACEPOINTS-is-not-en.patch \
|
|
file://0001-Fix-memory-leaks-on-event-destroy.patch \
|
|
file://0002-Fix-filter-interpreter-early-exits-on-uninitialized-.patch \
|
|
file://0003-fix-mm-tracing-record-slab-name-for-kmem_cache_free-.patch \
|
|
file://0004-Fix-kretprobe-null-ptr-deref-on-session-destroy.patch \
|
|
file://0005-fix-block-add-a-disk_uevent-helper-v5.12.patch \
|
|
file://0006-fix-backport-block-add-a-disk_uevent-helper-v5.12.patch \
|
|
file://0007-fix-mm-tracing-kfree-event-name-mismatching-with-pro.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "c4d1a1b42c728e37b6b7947ae16563a011c4b297311aa04d56f9a1791fb5a30a"
|
|
|
|
export INSTALL_MOD_DIR="kernel/lttng-modules"
|
|
|
|
EXTRA_OEMAKE += "KERNELDIR='${STAGING_KERNEL_DIR}'"
|
|
|
|
do_install_append() {
|
|
# Delete empty directories to avoid QA failures if no modules were built
|
|
find ${D}/${nonarch_base_libdir} -depth -type d -empty -exec rmdir {} \;
|
|
}
|
|
|
|
python do_package_prepend() {
|
|
if not os.path.exists(os.path.join(d.getVar('D'), d.getVar('nonarch_base_libdir')[1:], 'modules')):
|
|
bb.warn("%s: no modules were created; this may be due to CONFIG_TRACEPOINTS not being enabled in your kernel." % d.getVar('PN'))
|
|
}
|
|
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
LIC_FILES_CHKSUM_class-devupstream = "file://LICENSE;md5=3f882d431dc0f32f1f44c0707aa41128"
|
|
DEFAULT_PREFERENCE_class-devupstream = "-1"
|
|
SRC_URI_class-devupstream = "git://git.lttng.org/lttng-modules;branch=stable-2.12 \
|
|
file://Makefile-Do-not-fail-if-CONFIG_TRACEPOINTS-is-not-en.patch \
|
|
"
|
|
|
|
SRCREV_class-devupstream = "92cc3e7f76a545a2cd4828576971f1eea83f4e68"
|
|
PV_class-devupstream = "2.12.5+git${SRCPV}"
|
|
S_class-devupstream = "${WORKDIR}/git"
|
|
SRCREV_FORMAT ?= "lttng_git"
|