mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 21:32:12 +02:00
641848ab75
Adjusting the tolerance to a more reasonable time given the load on the AB and given the high amount(100) of events some of the tests like `common_timeout` generates. [YOCTO #14163] (From OE-Core rev: d5d88c2293e8ebc958d1bce9af8f796024443be9) Signed-off-by: Yi Fan Yu <yifan.yu@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 38b36d2b90d570149e63816e68f457aea28a5092) Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
63 lines
2.0 KiB
BlitzBasic
63 lines
2.0 KiB
BlitzBasic
SUMMARY = "An asynchronous event notification library"
|
|
DESCRIPTION = "A software library that provides asynchronous event \
|
|
notification. The libevent API provides a mechanism to execute a callback \
|
|
function when a specific event occurs on a file descriptor or after a \
|
|
timeout has been reached. libevent also supports callbacks triggered \
|
|
by signals and regular timeouts"
|
|
HOMEPAGE = "http://libevent.org/"
|
|
BUGTRACKER = "https://github.com/libevent/libevent/issues"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "BSD & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=17f20574c0b154d12236d5fbe964f549"
|
|
|
|
SRC_URI = "https://github.com/libevent/libevent/releases/download/release-${PV}-stable/${BP}-stable.tar.gz \
|
|
file://Makefile-missing-test-dir.patch \
|
|
file://run-ptest \
|
|
file://0001-test-regress_dns.c-patch-out-tests-that-require-a-wo.patch \
|
|
file://0002-test-regress.h-Increase-default-timeval-tolerance-50.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "92e6de1be9ec176428fd2367677e61ceffc2ee1cb119035037a27d346b0403bb"
|
|
|
|
UPSTREAM_CHECK_URI = "http://libevent.org/"
|
|
|
|
S = "${WORKDIR}/${BPN}-${PV}-stable"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
|
|
|
|
inherit autotools
|
|
|
|
# Needed for Debian packaging
|
|
LEAD_SONAME = "libevent-2.1.so"
|
|
|
|
inherit ptest multilib_header
|
|
|
|
DEPENDS = "zlib"
|
|
|
|
PACKAGES_DYNAMIC = "^${PN}-.*$"
|
|
python split_libevent_libs () {
|
|
do_split_packages(d, '${libdir}', r'^libevent_([a-z]*)-.*\.so\..*', '${PN}-%s', '${SUMMARY} (%s)', prepend=True, allow_links=True)
|
|
}
|
|
PACKAGESPLITFUNCS_prepend = "split_libevent_libs "
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
do_install_append() {
|
|
rm ${D}${bindir}/event_rpcgen.py
|
|
rmdir ${D}${bindir}
|
|
oe_multilib_header event2/event-config.h
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/test
|
|
for file in ${B}/test/.libs/regress ${B}/test/.libs/test*
|
|
do
|
|
install -m 0755 $file ${D}${PTEST_PATH}/test
|
|
done
|
|
|
|
# handle multilib
|
|
sed -i s:@libdir@:${libdir}:g ${D}${PTEST_PATH}/run-ptest
|
|
}
|