mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 18:32:20 +02:00
36f6caae93
These script use /bin/sh as the interpreter, but contains bashism:
recipes-devtools/insserv/files/run-ptest
recipes-devtools/quilt/quilt/run-ptest
recipes-devtools/tcltk/tcl/run-ptest
recipes-extended/gawk/gawk-4.1.1/run-ptest
recipes-support/beecrypt/beecrypt/run-ptest
Fixed:
"==" -> "=" (should be -eq when integer)
"&>log" -> ">log 2>&1"
And quilt's test scripts requires bash, add bash to RDEPENDS_quilt-ptest
(From OE-Core rev: 70c6e0b84d3e17807cbea0677df2f0772a284130)
Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
60 lines
1.9 KiB
PHP
60 lines
1.9 KiB
PHP
SUMMARY = "Tool for working with series of patches"
|
|
HOMEPAGE = "http://savannah.nongnu.org/projects/quilt/"
|
|
SECTION = "devel"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
SRC_URI = "${SAVANNAH_GNU_MIRROR}/quilt/quilt-${PV}.tar.gz \
|
|
file://install.patch \
|
|
file://run-ptest \
|
|
file://Makefile \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "c0ef4beb58a6fa72563b955e70624b6e"
|
|
SRC_URI[sha256sum] = "2846788221aa8844c54f10239c7cbc5e88031859162bcc285449446c3cfffe52"
|
|
|
|
inherit autotools-brokensep ptest
|
|
|
|
EXTRA_OECONF_darwin += "--without-date \
|
|
--without-getopt \
|
|
"
|
|
|
|
PACKAGES += "guards guards-doc"
|
|
FILES_${PN} = "${sysconfdir} ${datadir}/quilt \
|
|
${bindir}/quilt ${libdir}/quilt"
|
|
FILES_guards = "${bindir}/guards"
|
|
FILES_${PN}-doc = "${mandir}/man1/quilt.1 ${docdir}/${BPN}"
|
|
FILES_guards-doc = "${mandir}/man1/guards.1"
|
|
|
|
RDEPENDS_${PN} = "bash"
|
|
|
|
EXTRA_OE_MAKE_ARGS_darwin ?= ""
|
|
EXTRA_OE_MAKE_ARGS ?= "BUILD_ROOT=${D}"
|
|
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_BASH=/bin/bash"
|
|
|
|
# quilt ignores DESTDIR
|
|
do_install () {
|
|
oe_runmake ${EXTRA_OE_MAKE_ARGS} install
|
|
# cleanup unpackaged files
|
|
rm -rf ${D}/${datadir}/emacs
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake bin/patch-wrapper test/.depend
|
|
}
|
|
|
|
do_install_ptest() {
|
|
tar -cf - bin/ --exclude \*.in | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
tar -cf - compat/ --exclude \*.in | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
tar -cf - quilt/ --exclude \*.in | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
tar -cf - test/ --exclude mail.test --exclude delete.test | ( cd ${D}${PTEST_PATH} && tar -xf - )
|
|
cp ${WORKDIR}/Makefile ${D}${PTEST_PATH}
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest = "make file sed gawk diffutils findutils ed perl \
|
|
perl-module-filehandle perl-module-getopt-std \
|
|
perl-module-posix perl-module-file-temp \
|
|
perl-module-text-parsewords bash \
|
|
"
|