mirror of
https://git.yoctoproject.org/poky
synced 2026-04-01 23:02:21 +02:00
ff9c4b0141
When building G-I we want to use *native* binaries (as they need to be executed) but the *cross* libraries, as otherwise when using the correct pkg-config binary in native lookups Meson will end up linking native and cross libraries together. (From OE-Core rev: 958d7f8cebe863705dc6710b671764879ea68575) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
2.1 KiB
PHP
49 lines
2.1 KiB
PHP
HOMEPAGE = "http://mesonbuild.com"
|
|
SUMMARY = "A high performance build system"
|
|
DESCRIPTION = "Meson is a build system designed to increase programmer \
|
|
productivity. It does this by providing a fast, simple and easy to use \
|
|
interface for modern software development tools and practices."
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
|
|
SRC_URI = "https://github.com/mesonbuild/meson/releases/download/${PV}/meson-${PV}.tar.gz \
|
|
file://0001-gtkdoc-fix-issues-that-arise-when-cross-compiling.patch \
|
|
file://0003-native_bindir.patch \
|
|
file://0001-python-module-do-not-manipulate-the-environment-when.patch \
|
|
file://disable-rpath-handling.patch \
|
|
file://cross-prop-default.patch \
|
|
file://0001-modules-python.py-do-not-substitute-python-s-install.patch \
|
|
file://0001-minstall-Correctly-set-uid-gid-of-installed-files.patch \
|
|
file://gi-target-dep.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "72e1c782ba9bda204f4a1ed57f98d027d7b6eb9414c723eebbd6ec7f1955c8a6"
|
|
|
|
SRC_URI_append_class-native = " \
|
|
file://0001-Make-CPU-family-warnings-fatal.patch \
|
|
file://0002-Support-building-allarch-recipes-again.patch \
|
|
"
|
|
|
|
# remove at next version upgrade or when output changes
|
|
PR = "r1"
|
|
HASHEQUIV_HASH_VERSION .= ".1"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/mesonbuild/meson/releases"
|
|
UPSTREAM_CHECK_REGEX = "meson-(?P<pver>\d+(\.\d+)+)\.tar"
|
|
|
|
inherit setuptools3
|
|
|
|
RDEPENDS_${PN} = "ninja python3-modules python3-pkg-resources"
|
|
|
|
FILES_${PN} += "${datadir}/polkit-1"
|
|
|
|
do_install_append () {
|
|
# As per the same issue in the python recipe itself:
|
|
# Unfortunately the following pyc files are non-deterministc due to 'frozenset'
|
|
# being written without strict ordering, even with PYTHONHASHSEED = 0
|
|
# Upstream is discussing ways to solve the issue properly, until then let's
|
|
# just not install the problematic files.
|
|
# More info: http://benno.id.au/blog/2013/01/15/python-determinism
|
|
rm ${D}${libdir}/python*/site-packages/mesonbuild/dependencies/__pycache__/mpi.cpython*
|
|
}
|