mirror of
https://git.yoctoproject.org/poky
synced 2026-04-02 08:02:23 +02:00
ef39fa61d5
With a bit of help from upstream I figured out how to do cross-builds the way upstream intends to. (From OE-Core rev: f13c2cd727b01a3a11211a42c682ebb5eef9aa11) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
2.0 KiB
BlitzBasic
47 lines
2.0 KiB
BlitzBasic
SUMMARY = "iCal and scheduling (RFC 2445, 2446, 2447) library"
|
|
DESCRIPTION = "An Open Source implementation of the iCalendar protocols \
|
|
and protocol data units. The iCalendar specification describes how \
|
|
calendar clients can communicate with calendar servers so users can store \
|
|
their calendar data and arrange meetings with other users. "
|
|
HOMEPAGE = "https://github.com/libical/libical"
|
|
BUGTRACKER = "https://github.com/libical/libical/issues"
|
|
LICENSE = "LGPLv2.1 | MPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=1910a2a76ddf6a9ba369182494170d87 \
|
|
file://LICENSE.LGPL21.txt;md5=933adb561f159e7c3da079536f0ed871 \
|
|
file://LICENSE.MPL2.txt;md5=f75d2927d3c1ed2414ef72048f5ad640 \
|
|
"
|
|
SECTION = "libs"
|
|
|
|
SRC_URI = "https://github.com/${BPN}/${BPN}/releases/download/v${PV}/${BP}.tar.gz \
|
|
"
|
|
SRC_URI[sha256sum] = "bd26d98b7fcb2eb0cd5461747bbb02024ebe38e293ca53a7dfdcb2505265a728"
|
|
UPSTREAM_CHECK_URI = "https://github.com/libical/libical/releases"
|
|
|
|
inherit cmake pkgconfig
|
|
|
|
DEPENDS_append_class-target = "libical-native"
|
|
|
|
PACKAGECONFIG ??= "icu glib"
|
|
PACKAGECONFIG[bdb] = ",-DCMAKE_DISABLE_FIND_PACKAGE_BDB=True,db"
|
|
PACKAGECONFIG[glib] = "-DICAL_GLIB=True,-DICAL_GLIB=False,glib-2.0-native libxml2-native glib-2.0 libxml2"
|
|
# ICU is used for RSCALE (RFC7529) support
|
|
PACKAGECONFIG[icu] = ",-DCMAKE_DISABLE_FIND_PACKAGE_ICU=True,icu"
|
|
|
|
# No need to use perl-native, the host perl is sufficient.
|
|
EXTRA_OECMAKE += "-DPERL_EXECUTABLE=${HOSTTOOLS_DIR}/perl"
|
|
# doc build fails with linker error (??) for libical-glib so disable it
|
|
EXTRA_OECMAKE += "-DICAL_BUILD_DOCS=false"
|
|
|
|
EXTRA_OECMAKE_append_class-target = " -DIMPORT_ICAL_GLIB_SRC_GENERATOR=${STAGING_LIBDIR_NATIVE}/cmake/LibIcal/IcalGlibSrcGenerator.cmake"
|
|
|
|
do_install_append () {
|
|
# Remove build host references
|
|
sed -i \
|
|
-e 's,${STAGING_LIBDIR},${libdir},g' \
|
|
-e 's,${STAGING_INCDIR},${includedir},g' \
|
|
${D}${libdir}/cmake/LibIcal/LibIcal*.cmake \
|
|
${D}${libdir}/cmake/LibIcal/Ical*.cmake
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|