mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
9f2def3811
https://cryptography.io/en/latest/changelog/#v39-0-1 39.0.1 - 2023-02-07 * SECURITY ISSUE - Fixed a bug where Cipher.update_into accepted Python buffer protocol objects, but allowed immutable buffers. CVE-2023-23931 * Updated Windows, macOS, and Linux wheels to be compiled with OpenSSL 3.0.8. CVE: CVE-2023-23931 (From OE-Core rev: b2883bb86d8d0f7929b3c7a40f603010fbe153a4) Signed-off-by: Tim Orling <tim.orling@konsulko.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
72 lines
2.1 KiB
BlitzBasic
72 lines
2.1 KiB
BlitzBasic
SUMMARY = "Provides cryptographic recipes and primitives to python developers"
|
|
HOMEPAGE = "https://cryptography.io/"
|
|
SECTION = "devel/python"
|
|
LICENSE = "( Apache-2.0 | BSD-3-Clause ) & PSF-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=bf405a8056a6647e7d077b0e7bc36aba \
|
|
file://LICENSE.APACHE;md5=4e168cce331e5c827d4c2b68a6200e1b \
|
|
file://LICENSE.BSD;md5=5ae30ba4123bc4f2fa49aa0b0dce887b \
|
|
file://LICENSE.PSF;md5=43c37d21e1dbad10cddcd150ba2c0595 \
|
|
"
|
|
LDSHARED += "-pthread"
|
|
|
|
SRC_URI[sha256sum] = "d1f6198ee6d9148405e49887803907fe8962a23e6c6f83ea7d98f1c0de375695"
|
|
|
|
SRC_URI += "\
|
|
file://0002-Cargo.toml-edition-2018-2021.patch \
|
|
file://0001-pyproject.toml-remove-benchmark-disable-option.patch \
|
|
file://check-memfree.py \
|
|
file://run-ptest \
|
|
"
|
|
|
|
require ${BPN}-crates.inc
|
|
|
|
inherit pypi python_setuptools3_rust cargo-update-recipe-crates
|
|
|
|
DEPENDS += " \
|
|
${PYTHON_PN}-cffi-native \
|
|
"
|
|
|
|
RDEPENDS:${PN} += " \
|
|
${PYTHON_PN}-cffi \
|
|
"
|
|
|
|
RDEPENDS:${PN}:append:class-target = " \
|
|
${PYTHON_PN}-numbers \
|
|
${PYTHON_PN}-threading \
|
|
"
|
|
|
|
RDEPENDS:${PN}-ptest += " \
|
|
${PYTHON_PN}-bcrypt \
|
|
${PYTHON_PN}-cryptography-vectors (= ${PV}) \
|
|
${PYTHON_PN}-hypothesis \
|
|
${PYTHON_PN}-iso8601 \
|
|
${PYTHON_PN}-pretend \
|
|
${PYTHON_PN}-psutil \
|
|
${PYTHON_PN}-pytest \
|
|
${PYTHON_PN}-pytest-subtests \
|
|
${PYTHON_PN}-pytz \
|
|
"
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
install -D ${WORKDIR}/check-memfree.py ${D}${PTEST_PATH}/
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
|
|
# remove test_x509.py as it needs benchmark and we don't
|
|
# want to introduce the benchmark dependency
|
|
rm -rf ${D}${PTEST_PATH}/tests/bench/test_x509.py
|
|
install -d ${D}${PTEST_PATH}/tests/hazmat
|
|
cp -rf ${S}/tests/hazmat/* ${D}${PTEST_PATH}/tests/hazmat/
|
|
cp -r ${S}/pyproject.toml ${D}${PTEST_PATH}/
|
|
}
|
|
|
|
FILES:${PN}-ptest += " \
|
|
${PTEST_PATH}/check-memfree.py \
|
|
"
|
|
FILES:${PN}-dbg += " \
|
|
${PYTHON_SITEPACKAGES_DIR}/${SRCNAME}/hazmat/bindings/.debug \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|