mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 21:32:12 +02:00
74e2f682bb
The reasons for the switch are here: http://lists.openembedded.org/pipermail/openembedded-core/2015-July/107091.html http://lists.openembedded.org/pipermail/openembedded-core/2016-January/116007.html Changes made to libav recipe: - drop libav-fix-CVE-2014-9676.patch, the fix is available upstream - merge .inc into .bb, only one upstream version (latest one) is provided - drop separate libpostproc recipe, the library is provided directly from ffmpeg source tree - drop ARM tweaks; they date to classic-OE, need to be retested against the new code and probably haven't been relevant for a long time - drop PACKAGECONFIG options that are no longer provided upstream - drop build and packaging tweaks that don't seem to do anything useful and also date back to classic OE; if you run into issues, please report - explicitly enable PIC and disable stripping of binaries (From OE-Core rev: 77dbf07293df15cd5473422abd678930d6277bb0) Signed-off-by: Alexander Kanavin <alexander.kanavin@linux.intel.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
112 lines
4.7 KiB
BlitzBasic
112 lines
4.7 KiB
BlitzBasic
SUMMARY = "A complete, cross-platform solution to record, convert and stream audio and video."
|
|
DESCRIPTION = "FFmpeg is the leading multimedia framework, able to decode, encode, transcode, \
|
|
mux, demux, stream, filter and play pretty much anything that humans and machines \
|
|
have created. It supports the most obscure ancient formats up to the cutting edge."
|
|
HOMEPAGE = "https://www.ffmpeg.org/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "GPLv2+"
|
|
LICENSE_FLAGS = "commercial"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING.GPLv2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://COPYING.GPLv3;md5=d32239bcb673463ab874e80d47fae504 \
|
|
file://COPYING.LGPLv2.1;md5=bd7a443320af8c812e4c18d1b79df004 \
|
|
file://COPYING.LGPLv3;md5=e6a600fd5e1d9cbde2d983680233ad02"
|
|
|
|
SRC_URI = "https://www.ffmpeg.org/releases/${BP}.tar.xz"
|
|
|
|
SRC_URI[md5sum] = "b34164bd181f4f81c21da3dd131d919d"
|
|
SRC_URI[sha256sum] = "76fb83a267d2d1cb332742dadf28ad8b58af7958165f51bb1a2c226a122f0ac7"
|
|
|
|
# Should be API compatible with libav (which was a fork of ffmpeg)
|
|
# libpostproc was previously packaged from a separate recipe
|
|
PROVIDES = "libav libpostproc"
|
|
|
|
DEPENDS = "alsa-lib zlib libogg yasm-native libxv"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
PACKAGECONFIG ??= "avdevice avfilter gpl theora x264 ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
|
|
PACKAGECONFIG[avdevice] = "--enable-avdevice,--disable-avdevice"
|
|
PACKAGECONFIG[avfilter] = "--enable-avfilter,--disable-avfilter"
|
|
PACKAGECONFIG[faac] = "--enable-libfaac,--disable-libfaac,faac"
|
|
PACKAGECONFIG[gpl] = "--enable-gpl,--disable-gpl"
|
|
PACKAGECONFIG[gsm] = "--enable-libgsm,--disable-libgsm,libgsm"
|
|
PACKAGECONFIG[jack] = "--enable-indev=jack,--disable-indev=jack,jack"
|
|
PACKAGECONFIG[libvorbis] = "--enable-libvorbis,--disable-libvorbis,libvorbis"
|
|
PACKAGECONFIG[mp3lame] = "--enable-libmp3lame,--disable-libmp3lame,lame"
|
|
PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
|
|
PACKAGECONFIG[schroedinger] = "--enable-libschroedinger,--disable-libschroedinger,schroedinger"
|
|
PACKAGECONFIG[speex] = "--enable-libspeex,--disable-libspeex,speex"
|
|
PACKAGECONFIG[theora] = "--enable-libtheora,--disable-libtheora,libtheora"
|
|
PACKAGECONFIG[vaapi] = "--enable-vaapi,--disable-vaapi,libva"
|
|
PACKAGECONFIG[vpx] = "--enable-libvpx,--disable-libvpx,libvpx"
|
|
PACKAGECONFIG[x11] = "--enable-x11grab,--disable-x11grab,virtual/libx11 libxfixes libxext xproto virtual/libsdl"
|
|
PACKAGECONFIG[x264] = "--enable-libx264,--disable-libx264,x264"
|
|
|
|
# Check codecs that require --enable-nonfree
|
|
USE_NONFREE = "${@bb.utils.contains_any('PACKAGECONFIG', [ 'faac', 'openssl' ], 'yes', '', d)}"
|
|
|
|
EXTRA_OECONF = " \
|
|
--disable-stripping \
|
|
--enable-pic \
|
|
--enable-shared \
|
|
--enable-pthreads \
|
|
${@bb.utils.contains('USE_NONFREE', 'yes', '--enable-nonfree', '', d)} \
|
|
\
|
|
--cross-prefix=${TARGET_PREFIX} \
|
|
\
|
|
--ld="${CCLD}" \
|
|
--arch=${TARGET_ARCH} \
|
|
--target-os="linux" \
|
|
--enable-cross-compile \
|
|
--extra-cflags="${TARGET_CFLAGS} ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}" \
|
|
--extra-ldflags="${TARGET_LDFLAGS}" \
|
|
--sysroot="${STAGING_DIR_TARGET}" \
|
|
--enable-hardcoded-tables \
|
|
${EXTRA_FFCONF} \
|
|
--libdir=${libdir} \
|
|
--shlibdir=${libdir} \
|
|
--datadir=${datadir}/ffmpeg \
|
|
"
|
|
|
|
do_configure() {
|
|
${S}/configure ${EXTRA_OECONF}
|
|
}
|
|
|
|
RSUGGESTS_${PN} = "mplayer"
|
|
PACKAGES_DYNAMIC += "^lib(av(codec|device|filter|format|util)|swscale).*"
|
|
|
|
python populate_packages_prepend() {
|
|
av_libdir = d.expand('${libdir}')
|
|
av_pkgconfig = d.expand('${libdir}/pkgconfig')
|
|
|
|
# Runtime package
|
|
do_split_packages(d, av_libdir, '^lib(.*)\.so\..*',
|
|
output_pattern='lib%s',
|
|
description='libav %s library',
|
|
extra_depends='',
|
|
prepend=True,
|
|
allow_links=True)
|
|
|
|
# Development packages (-dev, -staticdev)
|
|
do_split_packages(d, av_libdir, '^lib(.*)\.so$',
|
|
output_pattern='lib%s-dev',
|
|
description='libav %s development package',
|
|
extra_depends='${PN}-dev',
|
|
prepend=True,
|
|
allow_links=True)
|
|
do_split_packages(d, av_pkgconfig, '^lib(.*)\.pc$',
|
|
output_pattern='lib%s-dev',
|
|
description='libav %s development package',
|
|
extra_depends='${PN}-dev',
|
|
prepend=True)
|
|
do_split_packages(d, av_libdir, '^lib(.*)\.a$',
|
|
output_pattern='lib%s-staticdev',
|
|
description='libav %s development package - static library',
|
|
extra_depends='${PN}-dev',
|
|
prepend=True,
|
|
allow_links=True)
|
|
|
|
}
|