mirror of
https://git.yoctoproject.org/poky
synced 2026-04-24 03:32:13 +02:00
559dba8cc0
* Remove backported patches: 0001-Move-gcc-compat-macros-to-gcc_compat.h.patch 0001-arc-metag-nios2-or1k-tile-fix-build.patch 0001-scm_rights-fd.test-rewrite-without-fork.patch 0001-tests-introduce-libtests.patch 0001-tests-scm_rights.c-use-libtests.patch * Update update-gawk-paths.patch (From OE-Core rev: 53b3d06d24ad711241fe706d100d888a06669d57) Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.6 KiB
BlitzBasic
48 lines
1.6 KiB
BlitzBasic
SUMMARY = "System call tracing tool"
|
|
HOMEPAGE = "http://strace.sourceforge.net"
|
|
SECTION = "console/utils"
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=124500c21e856f0912df29295ba104c7"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/strace/strace-${PV}.tar.xz \
|
|
file://disable-git-version-gen.patch \
|
|
file://more-robust-test-for-m32-mx32-compile-support.patch \
|
|
file://update-gawk-paths.patch \
|
|
file://use-asm-sgidefs.h.patch \
|
|
file://Makefile-ptest.patch \
|
|
file://run-ptest \
|
|
file://0001-Fix-build-when-using-non-glibc-libc-implementation-o.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "efb8611fc332e71ec419c53f59faa93e"
|
|
SRC_URI[sha256sum] = "51144b78cb9ba22211b95a5aafe0af3694c0d575b25975d80ca9dd4dfd7c1e59"
|
|
|
|
inherit autotools ptest bluetooth
|
|
|
|
RDEPENDS_${PN}-ptest += "make coreutils grep gawk sed"
|
|
|
|
PACKAGECONFIG_class-target ??= "\
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,${BLUEZ}"
|
|
PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
|
|
|
|
TESTDIR = "tests"
|
|
|
|
do_install_append() {
|
|
# We don't ship strace-graph here because it needs perl
|
|
rm ${D}${bindir}/strace-graph
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C ${TESTDIR} buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest() {
|
|
oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
|
|
sed -i -e '/^src/s/strace.*[1-9]/ptest/' ${D}/${PTEST_PATH}/${TESTDIR}/Makefile
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|