mirror of
https://git.yoctoproject.org/poky
synced 2026-09-24 22:36:21 +02:00
170ce893e7
zgrep applied to a crafted file name with two or more newlines can no longer overwrite an arbitrary, attacker-selected file. Upstream-Status: Backport [https://git.savannah.gnu.org/cgit/gzip.git/commit/?id=dc9740df61e575e8c3148b7bd3c147a81ea00c7c] CVE: CVE-2022-1271 (From OE-Core rev: b7f0696bc60409af215549d26621526c1a93a002) Signed-off-by: Ralph Siemsen <ralph.siemsen@linaro.org> Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.5 KiB
BlitzBasic
42 lines
1.5 KiB
BlitzBasic
require gzip.inc
|
|
|
|
LICENSE = "GPLv3+"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/gzip/${BP}.tar.gz \
|
|
file://run-ptest \
|
|
file://CVE-2022-1271.patch \
|
|
"
|
|
SRC_URI_append_class-target = " file://wrong-path-fix.patch"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504 \
|
|
file://gzip.h;beginline=8;endline=20;md5=6e47caaa630e0c8bf9f1bc8d94a8ed0e"
|
|
|
|
PROVIDES_append_class-native = " gzip-replacement-native"
|
|
|
|
RDEPENDS_${PN}-ptest += "make perl grep diffutils"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
mkdir -p ${D}${PTEST_PATH}/src/build-aux
|
|
cp ${S}/build-aux/test-driver ${D}${PTEST_PATH}/src/build-aux/
|
|
mkdir -p ${D}${PTEST_PATH}/src/tests
|
|
cp -r ${S}/tests/* ${D}${PTEST_PATH}/src/tests
|
|
sed -e 's/^abs_srcdir = ..*/abs_srcdir = \.\./' \
|
|
-e 's/^top_srcdir = ..*/top_srcdir = \.\./' \
|
|
-e 's/^GREP = ..*/GREP = grep/' \
|
|
-e 's/^AWK = ..*/AWK = awk/' \
|
|
-e 's/^srcdir = ..*/srcdir = \./' \
|
|
-e 's/^Makefile: ..*/Makefile: /' \
|
|
-e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
|
|
-e 's|${DEBUG_PREFIX_MAP}||g' \
|
|
-e 's:${HOSTTOOLS_DIR}/::g' \
|
|
-e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
|
|
${B}/tests/Makefile > ${D}${PTEST_PATH}/src/tests/Makefile
|
|
}
|
|
|
|
SRC_URI[md5sum] = "cf9ee51aff167ff69844d5d7d71c8b20"
|
|
SRC_URI[sha256sum] = "c91f74430bf7bc20402e1f657d0b252cb80aa66ba333a25704512af346633c68"
|